3 files changed, 122 insertions, 0 deletions
diff --git a/packages/nix/NIX.md b/packages/nix/NIX.md
new file mode 100644
index 00000000..1ceba9a3
--- /dev/null
+++ b/packages/nix/NIX.md
@@ -0,0 +1,31 @@
+# How to import
+
+To import with flakes use
+```nix
+inputs = {
+  polymc.url = "github:PolyMC/PolyMC";
+};
+
+...
+
+nixpkgs.overlays = [ inputs.polymc.overlay ]; ## Within configuration.nix
+environment.systemPackages = with pkgs; [ polymc ]; ##
+```
+
+To import without flakes use channels:
+
+```
+nix-channel --add https://github.com/PolyMC/PolyMC/archive/master.tar.gz polymc
+nix-channel --update polymc
+nix-env -iA polymc
+```
+
+or alternatively you can use
+
+```
+nixpkgs.overlays = [
+  (import (builtins.fetchTarball "https://github.com/PolyMC/PolyMC/archive/develop.tar.gz")).overlay
+];
+
+environment.systemPackages = with pkgs; [ polymc ];
+```
diff --git a/packages/nix/flake-compat.nix b/packages/nix/flake-compat.nix
new file mode 100644
index 00000000..bb7ee13e
--- /dev/null
+++ b/packages/nix/flake-compat.nix
@@ -0,0 +1,9 @@
+let
+  lock = builtins.fromJSON (builtins.readFile ../../flake.lock);
+  inherit (lock.nodes.flake-compat.locked) rev narHash;
+  flake-compat = fetchTarball {
+    url = "https://github.com/edolstra/flake-compat/archive/${rev}.tar.gz";
+    sha256 = narHash;
+  };
+in
+import flake-compat { src = ../..; }
diff --git a/packages/nix/polymc/default.nix b/packages/nix/polymc/default.nix
new file mode 100644
index 00000000..e65a7e34
--- /dev/null
+++ b/packages/nix/polymc/default.nix
@@ -0,0 +1,82 @@
+{ lib
+, mkDerivation
+, fetchFromGitHub
+, cmake
+, ninja
+, jdk8
+, jdk
+, zlib
+, file
+, makeWrapper
+, xorg
+, libpulseaudio
+, qtbase
+, libGL
+, msaClientID ? ""
+
+# flake
+, self
+, submoduleNbt
+, submoduleQuazip
+}:
+
+let
+  # Libraries required to run Minecraft
+  libpath = with xorg; lib.makeLibraryPath [
+    libX11
+    libXext
+    libXcursor
+    libXrandr
+    libXxf86vm
+    libpulseaudio
+    libGL
+  ]; 
+
+  # This variable will be passed to Minecraft by PolyMC
+  gameLibraryPath = libpath + ":/run/opengl-driver/lib";
+in
+
+mkDerivation rec {
+  pname = "polymc";
+  version = "nightly";
+
+  src = lib.cleanSource self;
+
+  nativeBuildInputs = [ cmake ninja file makeWrapper ];
+  buildInputs = [ qtbase jdk8 zlib ];
+
+  dontWrapQtApps = true;
+
+  postPatch = ''
+    # hardcode jdk paths
+    substituteInPlace launcher/java/JavaUtils.cpp \
+      --replace 'scanJavaDir("/usr/lib/jvm")' 'javas.append("${jdk}/lib/openjdk/bin/java")' \
+      --replace 'scanJavaDir("/usr/lib32/jvm")' 'javas.append("${jdk8}/lib/openjdk/bin/java")'
+  '' + lib.optionalString (msaClientID != "") ''
+    # add client ID
+    substituteInPlace CMakeLists.txt \
+      --replace '17b47edd-c884-4997-926d-9e7f9a6b4647' '${msaClientID}'
+  '';
+
+  postUnpack = ''
+    # Copy submodules inputs
+    rm -rf source/libraries/{libnbtplusplus,quazip}
+    mkdir source/libraries/{libnbtplusplus,quazip}
+    cp -a ${submoduleNbt}/* source/libraries/libnbtplusplus
+    cp -a ${submoduleQuazip}/* source/libraries/quazip
+    chmod a+r+w source/libraries/{libnbtplusplus,quazip}/*
+  '';
+
+  cmakeFlags = [
+    "-GNinja"
+    "-DLauncher_LAYOUT=lin-system"
+  ];
+
+  postInstall = ''
+    # xorg.xrandr needed for LWJGL [2.9.2, 3) https://github.com/LWJGL/lwjgl/issues/128
+    wrapProgram $out/bin/polymc \
+      "''${qtWrapperArgs[@]}" \
+      --set GAME_LIBRARY_PATH ${gameLibraryPath} \
+      --prefix PATH : ${lib.makeBinPath [ xorg.xrandr ]}
+  '';
+}