Merge pull request #1 from romangraef/loom

Loomering

1 files changed, 93 insertions, 0 deletions

diff --git a/build.gradle.kts b/build.gradle.kts
new file mode 100644
index 0000000..6a04c49
--- /dev/null
+++ b/build.gradle.kts
@@ -0,0 +1,93 @@
+plugins {
+    idea
+    java
+    id("gg.essential.loom") version "0.10.0.+"
+    id("dev.architectury.architectury-pack200") version "0.1.3"
+    id("com.github.johnrengelman.shadow") version "7.1.2"
+}
+
+version = "1.14.3"
+group = "com.thatgravyboat.skyblockhud"
+
+
+java {
+    toolchain.languageVersion.set(JavaLanguageVersion.of(8))
+}
+
+loom {
+    launchConfigs {
+        "client" {
+            property("mixin.debug", "true")
+            property("asmhelper.verbose", "true")
+            arg("--tweakClass", "org.spongepowered.asm.launch.MixinTweaker")
+            arg("--mixin", "mixins.skyblockhud.json")
+        }
+    }
+    forge {
+        pack200Provider.set(dev.architectury.pack200.java.Pack200Adapter())
+        mixinConfig("mixins.skyblockhud.json")
+    }
+    mixin {
+        defaultRefmapName.set("mixins.skyblockhud.refmap.json")
+    }
+}
+
+sourceSets.main {
+    output.setResourcesDir(file("$buildDir/classes/java/main"))
+}
+
+repositories {
+    mavenCentral()
+    maven("https://repo.spongepowered.org/maven/")
+    maven("https://pkgs.dev.azure.com/djtheredstoner/DevAuth/_packaging/public/maven/v1")
+}
+
+dependencies {
+    minecraft("com.mojang:minecraft:1.8.9")
+    mappings("de.oceanlabs.mcp:mcp_stable:22-1.8.9")
+    forge("net.minecraftforge:forge:1.8.9-11.15.1.2318-1.8.9")
+
+
+    implementation("org.spongepowered:mixin:0.7.11-SNAPSHOT")
+    annotationProcessor("org.spongepowered:mixin:0.8.4-SNAPSHOT")
+
+    modRuntimeOnly("me.djtheredstoner:DevAuth-forge-legacy:1.1.0")
+}
+
+
+tasks.withType(Jar::class) {
+    manifest.attributes.run {
+        this["FMLCorePluginContainsFMLMod"] = "true"
+        this["ForceLoadAsMod"] = "true"
+        this["TweakClass"] = "org.spongepowered.asm.launch.MixinTweaker"
+        this["MixinConfigs"] = "mixins.skyblockhud.json"
+    }
+}
+
+tasks.processResources {
+    inputs.property("version", project.version)
+    filesMatching("mcmod.info") {
+        expand(
+            "version" to project.version
+        )
+    }
+}
+
+tasks.shadowJar {
+    dependencies {
+        include(dependency("org.spongepowered:mixin:0.7.11-SNAPSHOT"))
+    }
+    exclude ("LICENSE.txt")
+
+    archiveClassifier.set("dep-dev")
+}
+
+
+val remapJar by tasks.named<net.fabricmc.loom.task.RemapJarTask>("remapJar") {
+    archiveClassifier.set("all")
+    from(tasks.shadowJar)
+    input.set(tasks.shadowJar.get().archiveFile)
+}
+
+tasks.assemble.get().dependsOn(tasks.remapJar)
+