plugins {
	id 'fabric-loom' version '1.4-SNAPSHOT'
	id 'maven-publish'
	id 'com.modrinth.minotaur' version '2.+'
}

version = "${project.mod_version}+${project.minecraft_version}"
group = project.maven_group

repositories {
	// Add repositories to retrieve artifacts from in here.
	// You should only use this when depending on other mods because
	// Loom adds the essential maven repositories to download Minecraft and libraries from automatically.
	// See https://docs.gradle.org/current/userguide/declaring_repositories.html
	// for more information about repositories.
	flatDir {
		dirs 'libs'
	}
	maven { url "https://maven.terraformersmc.com/releases" }
	maven { url "https://maven.shedaniel.me/" }
	maven { url "https://maven.isxander.dev/releases" }
	maven {
		url 'https://repo.maven.apache.org/maven2'
		name 'Maven Central'
	}
	maven {
		name = "meteor-maven"
		url = "https://maven.meteordev.org/releases"
	}
	maven { url "https://repo.codemc.io/repository/maven-public/" } // For Occlusion Culling library
	maven { url "https://repo.nea.moe/releases" } // For neu repoparser
	maven { url "https://oss.sonatype.org/content/repositories/snapshots" } //For YACL
	maven { url "https://maven.quiltmc.org/repository/release" } //For YACL
	maven {url "https://jitpack.io"}
}

dependencies {
	testImplementation 'org.junit.jupiter:junit-jupiter-api:5.9.2'
	testRuntimeOnly 'org.junit.jupiter:junit-jupiter-engine:5.9.2'
	// To change the versions see the gradle.properties file
	minecraft "com.mojang:minecraft:${project.minecraft_version}"
	mappings "net.fabricmc:yarn:${project.yarn_mappings}:v2"
	modImplementation "net.fabricmc:fabric-loader:${project.loader_version}"

	// Fabric API
	modImplementation "net.fabricmc.fabric-api:fabric-api:${project.fabric_api_version}"

	// YACL
	include modImplementation("dev.isxander.yacl:yet-another-config-lib-fabric:${project.yacl_version}")

	// Mod Menu
	modImplementation "com.terraformersmc:modmenu:${project.mod_menu_version}"

	// REI
	modCompileOnly "me.shedaniel:RoughlyEnoughItems-api-fabric:${project.rei_version}"
	modRuntimeOnly "me.shedaniel:RoughlyEnoughItems-fabric:${project.rei_version}"

	// EMI
	modCompileOnly "dev.emi:emi-fabric:${project.emi_version}:api"
	modLocalRuntime "dev.emi:emi-fabric:${project.emi_version}"

	// Renderer (https://github.com/0x3C50/Renderer)
	include modImplementation("com.github.0x3C50:Renderer:${project.renderer_version}") {
		exclude group: "io.github.ladysnake" exclude module: "satin"
	}

	include modImplementation("meteordevelopment:discord-ipc:1.1")

	// Mixin Extras (https://github.com/LlamaLad7/MixinExtras)
	include implementation(annotationProcessor("com.github.llamalad7.mixinextras:mixinextras-fabric:${project.mixin_extras_version}"))

	// BetterInject (https://github.com/caoimhebyrne/BetterInject)
	include implementation(annotationProcessor("com.github.cbyrneee:BetterInject:${project.betterinject_version}"))

	// https://mvnrepository.com/artifact/org.eclipse.jgit/org.eclipse.jgit used pull data from the NEU item repo
	include implementation("org.eclipse.jgit:org.eclipse.jgit:6.4.0.202211300538-r")

	// Occlusion Culling (https://github.com/LogisticsCraft/OcclusionCulling)
	include implementation("com.logisticscraft:occlusionculling:${project.occlusionculling_version}")

	// NEU RepoParser
	include implementation("moe.nea:neurepoparser:${project.repoparser_version}")
}

loom {
	accessWidenerPath = file("src/main/resources/skyblocker.accesswidener")
}

base {
	archivesName = project.archives_base_name
}

processResources {
	inputs.property "version", project.version

	filesMatching("fabric.mod.json") {
		expand "version": project.version
	}
}

tasks.withType(JavaCompile).configureEach {
	// ensure that the encoding is set to UTF-8, no matter what the system default is
	// this fixes some edge cases with special characters not displaying correctly
	// see http://yodaconditions.net/blog/fix-for-java-file-encoding-problems-with-gradle.html
	// If Javadoc is generated, this must be specified in that task too.


	// Minecraft 1.18 upwards uses Java 17.
	it.options.release = 17
}

java {
	// Loom will automatically attach sourcesJar to a RemapSourcesJar task and to the "build" task
	// if it is present.
	// If you remove this line, sources will not be generated.
	withSourcesJar()

	sourceCompatibility = JavaVersion.VERSION_17
	targetCompatibility = JavaVersion.VERSION_17
}

jar {
	from("LICENSE") {
		rename { "${it}_${base.archivesName.get()}"}
	}
}

test {
	useJUnitPlatform()
}

modrinth {
	token = System.getenv('MODRINTH_TOKEN')
	projectId = project.modrinth_id
	versionNumber = "v${project.version}"
	versionName = "Skyblocker ${project.mod_version} for ${project.minecraft_version}"
	uploadFile = remapJar
	gameVersions = [project.minecraft_version]
	loaders = ["fabric"]
	versionType = "release"
	dependencies {
		required.project "fabric-api"
		optional.project "modmenu"
		optional.project "rei"
		optional.project "emi"
	}
	changelog = System.getenv('CHANGELOG')
	syncBodyFrom = rootProject.file("MRREADME.md").text
}

tasks.modrinth.doLast {
	println "::set-output name=url::https://modrinth.com/mod/skyblocker-liap/version/$uploadInfo.id"
}

tasks.modrinth.dependsOn(tasks.modrinthSyncBody)

// configure the maven publication
publishing {
	publications {
		mavenJava(MavenPublication) {
			from components.java
		}
	}

	// See https://docs.gradle.org/current/userguide/publishing_maven.html for information on how to set up publishing.
	repositories {
		// Add repositories to publish to here.
		// Notice: This block does NOT have the same function as the block in the top level.
		// The repositories here will be used for publishing your artifact, not for
		// retrieving dependencies.
	}
}