1 files changed, 52 insertions, 0 deletions
diff --git a/common/build.gradle.kts b/common/build.gradle.kts
new file mode 100644
index 0000000..fb79bd1
--- /dev/null
+++ b/common/build.gradle.kts
@@ -0,0 +1,52 @@
+plugins {
+    alias(libs.plugins.architectury.loom)
+}
+
+base {
+    archivesName.set("yet-another-config-lib")
+}
+
+architectury {
+    common("fabric", "forge")
+}
+
+loom {
+    silentMojangMappingsLicense()
+
+    accessWidenerPath.set(file("src/main/resources/yacl.accesswidener"))
+}
+
+dependencies {
+    minecraft(libs.minecraft)
+    mappings(loom.layered {
+        mappings("org.quiltmc:quilt-mappings:${libs.versions.minecraft.get()}+build.${libs.versions.quilt.mappings.get()}:intermediary-v2")
+        officialMojangMappings()
+    })
+    modImplementation(libs.fabric.loader)
+}
+
+java {
+    withSourcesJar()
+}
+
+tasks {
+    remapJar {
+        archiveClassifier.set(null as String?)
+
+        from(rootProject.file("LICENSE"))
+    }
+}
+
+publishing {
+    publications {
+        create<MavenPublication>("common") {
+            groupId = "dev.isxander.yacl"
+            artifactId = "yet-another-config-lib-common"
+
+            from(components["java"])
+        }
+    }
+}
+tasks.findByPath("publishCommonPublicationToReleasesRepository")?.let {
+    rootProject.tasks["releaseMod"].dependsOn(it)
+}