Bump Gradle version, migrate to Kotlin DSL, refactor publishing

2 files changed, 43 insertions, 45 deletions

diff --git a/coreDependencies/build.gradle b/coreDependencies/build.gradle
deleted file mode 100644
index 2b166a93..00000000
--- a/coreDependencies/build.gradle
+++ /dev/null
@@ -1,45 +0,0 @@
-def intellijCoreAnalysis() {
-    return zipTree(project(":").configurations.intellijCore.singleFile).matching ({
-        include("intellij-core-analysis.jar")
-    })
-}
-
-apply plugin: 'java'
-apply plugin: 'com.github.johnrengelman.shadow'
-
-dependencies {
-    compile intellijCoreAnalysis()
-    compile "org.jetbrains.kotlin:kotlin-plugin-ij193:$kotlin_plugin_version" //TODO: parametrize ij version after 1.3.70
-}
-
-shadowJar {
-    baseName = 'dokka-dependencies'
-    classifier = ''
-
-    configurations {
-        exclude compileOnly
-    }
-
-
-    exclude 'colorScheme/**'
-    exclude 'fileTemplates/**'
-    exclude 'inspectionDescriptions/**'
-    exclude 'intentionDescriptions/**'
-    exclude 'tips/**'
-    exclude 'messages/**'
-
-    exclude 'src/**'
-}
-
-apply plugin: 'maven-publish'
-
-publishing {
-    publications {
-        dokkaDependencies(MavenPublication) { publication ->
-            artifactId = 'dokka-dependencies'
-            project.shadow.component(publication)
-        }
-    }
-}
-
-bintrayPublication(project, ["dokkaDependencies"])
\ No newline at end of file
diff --git a/coreDependencies/build.gradle.kts b/coreDependencies/build.gradle.kts
new file mode 100644
index 00000000..514c7ae1
--- /dev/null
+++ b/coreDependencies/build.gradle.kts
@@ -0,0 +1,43 @@
+plugins {
+    id("com.github.johnrengelman.shadow")
+    `maven-publish`
+}
+
+val intellijCore: Configuration by configurations.creating
+
+repositories {
+    maven(url = "https://www.jetbrains.com/intellij-repository/snapshots")
+    maven(url = "https://www.jetbrains.com/intellij-repository/releases")
+    maven(url = "https://kotlin.bintray.com/kotlin-plugin")
+}
+
+fun intellijCoreAnalysis() = zipTree(intellijCore.singleFile).matching {
+    include("intellij-core-analysis.jar")
+}
+
+dependencies {
+    val idea_version: String by project
+    intellijCore("com.jetbrains.intellij.idea:intellij-core:$idea_version")
+    val kotlin_plugin_version: String by project
+    implementation(intellijCoreAnalysis())
+    implementation("org.jetbrains.kotlin:kotlin-plugin-ij193:$kotlin_plugin_version") {
+        //TODO: parametrize ij version after 1.3.70
+        isTransitive = false
+    }
+}
+
+tasks {
+    shadowJar {
+        val dokka_version: String by project
+        archiveFileName.set("dokka-dependencies-$dokka_version.jar")
+        archiveClassifier.set("")
+
+        exclude("colorScheme/**")
+        exclude("fileTemplates/**")
+        exclude("inspectionDescriptions/**")
+        exclude("intentionDescriptions/**")
+        exclude("tips/**")
+        exclude("messages/**")
+        exclude("src/**")
+    }
+}