Migrate Dokka examples to Dokka repo (KT-47798) (#2030)

* Migrate Dokka examples to Dokka repo (KT-47798)

* Configure workflow of examples checking

* Add workflow to deploy examples

1 files changed, 44 insertions, 0 deletions

diff --git a/examples/gradle/dokka-library-publishing-example/build.gradle.kts b/examples/gradle/dokka-library-publishing-example/build.gradle.kts
new file mode 100644
index 00000000..1d94ae9e
--- /dev/null
+++ b/examples/gradle/dokka-library-publishing-example/build.gradle.kts
@@ -0,0 +1,44 @@
+plugins {
+    kotlin("jvm") version "1.4.32"
+    id("org.jetbrains.dokka") version ("1.4.32")
+    `java-library`
+    `maven-publish`
+}
+
+repositories {
+    mavenCentral()
+}
+
+dependencies {
+    implementation(kotlin("stdlib"))
+    testImplementation(kotlin("test-junit"))
+}
+
+val dokkaJavadocJar by tasks.register<Jar>("dokkaJavadocJar") {
+    dependsOn(tasks.dokkaJavadoc)
+    from(tasks.dokkaJavadoc.flatMap { it.outputDirectory })
+    archiveClassifier.set("javadoc")
+}
+
+val dokkaHtmlJar by tasks.register<Jar>("dokkaHtmlJar") {
+    dependsOn(tasks.dokkaHtml)
+    from(tasks.dokkaHtml.flatMap { it.outputDirectory })
+    archiveClassifier.set("html-doc")
+}
+
+publishing {
+    publications {
+        register<MavenPublication>("library") {
+            from(components["java"])
+            version = "1.0.0"
+            groupId = "demo"
+            artifactId = "dokka-library-publishing-example"
+            artifact(dokkaJavadocJar)
+            artifact(dokkaHtmlJar)
+        }
+    }
+}
+
+
+
+