Merge branch 'dev-0.11.0'

1 files changed, 41 insertions, 0 deletions

diff --git a/integration-tests/cli/build.gradle.kts b/integration-tests/cli/build.gradle.kts
new file mode 100644
index 00000000..d9961f8f
--- /dev/null
+++ b/integration-tests/cli/build.gradle.kts
@@ -0,0 +1,41 @@
+import com.github.jengelman.gradle.plugins.shadow.tasks.ShadowJar
+
+
+plugins {
+    id("com.github.johnrengelman.shadow")
+}
+
+val dokka_version: String by project
+evaluationDependsOn(":runners:cli")
+evaluationDependsOn(":plugins:base")
+
+dependencies {
+    implementation(kotlin("stdlib"))
+    implementation(kotlin("test-junit"))
+}
+
+/* Create a fat base plugin jar for cli tests */
+val basePluginShadow: Configuration by configurations.creating {
+    attributes {
+        attribute(Usage.USAGE_ATTRIBUTE, project.objects.named(Usage::class.java, "java-runtime"))
+    }
+}
+
+dependencies {
+    basePluginShadow(project(":plugins:base"))
+}
+val basePluginShadowJar by tasks.register("basePluginShadowJar", ShadowJar::class) {
+    configurations = listOf(basePluginShadow)
+    archiveFileName.set("fat-base-plugin-$dokka_version.jar")
+    archiveClassifier.set("")
+}
+
+tasks.integrationTest {
+    inputs.dir(file("projects"))
+    val cliJar = tasks.getByPath(":runners:cli:shadowJar") as ShadowJar
+    environment("CLI_JAR_PATH", cliJar.archiveFile.get())
+    environment("BASE_PLUGIN_JAR_PATH", basePluginShadowJar.archiveFile.get())
+    dependsOn(cliJar)
+    dependsOn(basePluginShadowJar)
+}
+