Bump Gradle version, migrate to Kotlin DSL, refactor publishing

2 files changed, 37 insertions, 16 deletions

diff --git a/runners/cli/build.gradle b/runners/cli/build.gradle
deleted file mode 100644
index 24db0b1e..00000000
--- a/runners/cli/build.gradle
+++ /dev/null
@@ -1,16 +0,0 @@
-apply plugin: 'kotlin'
-
-sourceCompatibility = 1.8
-
-tasks.withType(org.jetbrains.kotlin.gradle.tasks.KotlinCompile).all {
-    kotlinOptions {
-        languageVersion = language_version
-        apiVersion = language_version
-        jvmTarget = "1.8"
-    }
-}
-
-dependencies {
-    implementation "org.jetbrains.kotlinx:kotlinx-cli-jvm:0.1.0-dev-3"
-    implementation project(":core")
-}
diff --git a/runners/cli/build.gradle.kts b/runners/cli/build.gradle.kts
new file mode 100644
index 00000000..4b39d64c
--- /dev/null
+++ b/runners/cli/build.gradle.kts
@@ -0,0 +1,37 @@
+import org.jetbrains.configureBintrayPublication
+
+plugins {
+    id("com.github.johnrengelman.shadow")
+}
+
+repositories {
+    maven(url = "https://dl.bintray.com/orangy/maven")
+}
+
+dependencies {
+    implementation("org.jetbrains.kotlinx:kotlinx-cli-jvm:0.1.0-dev-3")
+    implementation(project(":core"))
+}
+
+
+tasks {
+    shadowJar {
+        val dokka_version: String by project
+        archiveFileName.set("dokka-cli-$dokka_version.jar")
+        archiveClassifier.set("")
+        manifest {
+            attributes("Main-Class" to "org.jetbrains.dokka.MainKt")
+        }
+    }
+}
+
+publishing {
+    publications {
+        register<MavenPublication>("dokkaCli") {
+            artifactId = "dokka-cli"
+            project.shadow.component(this)
+        }
+    }
+}
+
+configureBintrayPublication("dokkaCli")
\ No newline at end of file