1 files changed, 59 insertions, 0 deletions
diff --git a/build.gradle.kts b/build.gradle.kts
new file mode 100644
index 00000000..cae9ecca
--- /dev/null
+++ b/build.gradle.kts
@@ -0,0 +1,59 @@
+import org.jetbrains.ValidatePublications
+import org.jetbrains.configureDokkaVersion
+import org.jetbrains.kotlin.gradle.tasks.KotlinCompile
+
+plugins {
+    kotlin("jvm") apply false
+    id("java")
+}
+
+val dokka_version: String by project
+
+allprojects {
+    configureDokkaVersion()
+
+    group = "org.jetbrains.dokka"
+    version = dokka_version
+
+    val language_version: String by project
+    tasks.withType(KotlinCompile::class).all {
+        kotlinOptions {
+            freeCompilerArgs += "-Xjsr305=strict -Xskip-metadata-version-check -Xopt-in=kotlin.RequiresOptIn."
+            languageVersion = language_version
+            apiVersion = language_version
+            jvmTarget = "1.8"
+        }
+    }
+
+    repositories {
+        jcenter()
+        mavenCentral()
+        maven(url = "https://dl.bintray.com/kotlin/kotlin-eap")
+        maven(url = "https://dl.bintray.com/kotlin/kotlin-dev")
+    }
+}
+
+subprojects {
+    apply {
+        plugin("org.jetbrains.kotlin.jvm")
+        plugin("java")
+    }
+
+    // Gradle metadata
+    java {
+        @Suppress("UnstableApiUsage")
+        withSourcesJar()
+        targetCompatibility = JavaVersion.VERSION_1_8
+    }
+}
+
+// Workaround for https://github.com/bintray/gradle-bintray-plugin/issues/267
+//  Manually disable bintray tasks added to the root project
+tasks.whenTaskAdded {
+    if ("bintray" in name) {
+        enabled = false
+    }
+}
+
+println("Publication version: $dokka_version")
+tasks.register<ValidatePublications>("validatePublications")