From 769701f99a1aefbc9d385c1938c9c7d3a7b2e38e Mon Sep 17 00:00:00 2001
From: Simon Ogorodnik <sem-oro@yandex.ru>
Date: Tue, 1 Nov 2016 02:10:32 +0300
Subject: Total build refactoring, prepare for new development iteration

Removed old and useless build helpers

Remove old .xml's from .idea and add .idea/shelf to .gitignore

build-docs.xml fixed, dokka_version set to 0.9.10
---
 runners/fatjar/build.gradle | 62 +++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 62 insertions(+)
 create mode 100644 runners/fatjar/build.gradle

(limited to 'runners/fatjar')

diff --git a/runners/fatjar/build.gradle b/runners/fatjar/build.gradle
new file mode 100644
index 00000000..df20c9b9
--- /dev/null
+++ b/runners/fatjar/build.gradle
@@ -0,0 +1,62 @@
+import com.github.jengelman.gradle.plugins.shadow.transformers.ServiceFileTransformer
+import org.jetbrains.PluginXmlTransformer
+
+apply plugin: 'com.github.johnrengelman.shadow'
+
+dependencies {
+    compile project(":runners:cli")
+    compile project(":runners:ant")
+}
+
+shadowJar {
+    baseName = 'dokka-fatjar'
+    classifier = ''
+
+    configurations {
+        exclude provided
+    }
+
+    relocate('com.', 'dokkacom.') {
+        exclude 'com.sun.**'
+    }
+
+    relocate('org.', 'dokkaorg.') {
+        exclude 'org.jetbrains.dokka.**'
+        exclude 'org.xml.**'
+        exclude 'org.w3c.**'
+        exclude 'org.jaxen.**'
+        exclude 'org.apache.xerces.**'
+        exclude 'org.apache.xml.**'
+        exclude 'org.fusesource.jansi.**'
+        exclude 'org.apache.tools.ant.**'
+    }
+
+
+    relocate('kotlin.', 'dokkakotlin.') {
+        exclude '**.*kotlin_builtins' //For kotlin_builtins, still not sure that we should relocate kotlin stdlib
+        exclude 'kotlin.reflect' /* WAT? Ok, ok. Relocate works as Ctrl + Shift + R for ALL class files, so,
+        if you have string "kotlin.reflect", it will be rewritten to not relevant "dokkakotlin.reflect" and you will got
+        builtins crash in runtime, cause could not find dokkakotlin/reflect/reflect.kotlin_builtins */
+    }
+
+    transform(ServiceFileTransformer)
+    transform(PluginXmlTransformer)
+
+    exclude 'colorScheme/**'
+    exclude 'fileTemplates/**'
+    exclude 'inspectionDescriptions/**'
+    exclude 'intentionDescriptions/**'
+}
+
+apply plugin: 'maven-publish'
+
+publishing {
+    publications {
+        dokkaFatJar(MavenPublication) {
+            from components.shadow
+            artifactId = 'dokka-fatjar'
+        }
+    }
+}
+
+bintrayPublication(project, ["dokkaFatJar"])
\ No newline at end of file
-- 
cgit