From e99be615ce7c2c2b5c3ee5e3f8941c41c1e7a944 Mon Sep 17 00:00:00 2001
From: Kamil Doległo <kamilok1965@interia.pl>
Date: Fri, 31 Jan 2020 00:37:29 +0100
Subject: Bump Gradle version, migrate to Kotlin DSL, refactor publishing

---
 runners/gradle-plugin/build.gradle.kts | 74 ++++++++++++++++++++++++++++++++++
 1 file changed, 74 insertions(+)
 create mode 100644 runners/gradle-plugin/build.gradle.kts

(limited to 'runners/gradle-plugin/build.gradle.kts')

diff --git a/runners/gradle-plugin/build.gradle.kts b/runners/gradle-plugin/build.gradle.kts
new file mode 100644
index 00000000..0d68a525
--- /dev/null
+++ b/runners/gradle-plugin/build.gradle.kts
@@ -0,0 +1,74 @@
+import org.jetbrains.configureBintrayPublication
+
+plugins {
+    id("com.gradle.plugin-publish")
+}
+
+repositories {
+    google()
+}
+
+dependencies {
+    implementation(project(":core"))
+    compileOnly("org.jetbrains.kotlin:kotlin-gradle-plugin")
+    compileOnly("com.android.tools.build:gradle:3.0.0")
+    compileOnly("com.android.tools.build:gradle-core:3.0.0")
+    compileOnly("com.android.tools.build:builder-model:3.0.0")
+    compileOnly(gradleApi())
+    constraints {
+        val kotlin_version: String by project
+        compileOnly("org.jetbrains.kotlin:kotlin-reflect:${kotlin_version}") {
+            because("kotlin-gradle-plugin and :core both depend on this")
+        }
+    }
+}
+
+tasks {
+    processResources {
+        val dokka_version: String by project
+        eachFile {
+            if (name == "org.jetbrains.dokka.properties") {
+                filter { line ->
+                    line.replace("<version>", dokka_version)
+                }
+            }
+        }
+    }
+}
+
+val sourceJar by tasks.registering(Jar::class) {
+    archiveClassifier.set("sources")
+    from(sourceSets["main"].allSource)
+}
+
+publishing {
+    publications {
+        register<MavenPublication>("dokkaGradlePlugin") {
+            artifactId = "dokka-gradle-plugin"
+            from(components["java"])
+            artifact(sourceJar.get())
+        }
+    }
+}
+
+configureBintrayPublication("dokkaGradlePlugin") // TODO check if this publishes correctly
+
+pluginBundle {
+    // TODO check if this publishes correctly
+    website = "https://www.kotlinlang.org/"
+    vcsUrl = "https://github.com/kotlin/dokka.git"
+    description = "Dokka, the Kotlin documentation tool"
+    tags = listOf("dokka", "kotlin", "kdoc", "android")
+
+    plugins {
+        create("dokkaGradlePlugin") {
+            id = "org.jetbrains.dokka"
+            displayName = "Dokka plugin"
+        }
+    }
+
+    mavenCoordinates {
+        groupId = "org.jetbrains.dokka"
+        artifactId = "dokka-gradle-plugin"
+    }
+}
\ No newline at end of file
-- 
cgit