build.gradle


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51

plugins {
    id 'java-gradle-plugin'
}

repositories {
    mavenCentral()
}

group = 'ch.fhnw.thga'
version = '0.0.1-SNAPSHOT'

sourceSets {
    functionalTest {
        compileClasspath += sourceSets.main.output + sourceSets.test.output
        runtimeClasspath += sourceSets.test.runtimeClasspath
    }
}

gradlePlugin {
    testSourceSets project.sourceSets.functionalTest
    plugins {
        fregePlugin {
            id = 'ch.fhnw.thga.frege'
            implementationClass = 'ch.fhnw.thga.gradleplugins.FregePlugin'
        }
    }
}

configurations {
    functionalTestImplementation.extendsFrom testImplementation
    functionalRuntimeOnly.extendsFrom runtimeOnly
}

tasks.register('functionalTest', Test) {
    description = 'Runs functional tests.'
    group = 'verification'
    testClassesDirs = sourceSets.functionalTest.output.classesDirs
    classpath = sourceSets.functionalTest.runtimeClasspath
    shouldRunAfter test
}

check.dependsOn functionalTest

tasks.withType(Test).configureEach {
    useJUnitPlatform()
}

dependencies {
    testImplementation('org.junit.jupiter:junit-jupiter-api:5.7.2')
    testRuntimeOnly('org.junit.jupiter:junit-jupiter-engine:5.7.2')
}