1 files changed, 68 insertions, 0 deletions
diff --git a/kvision-modules/kvision-bootstrap-select/build.gradle.kts b/kvision-modules/kvision-bootstrap-select/build.gradle.kts
new file mode 100644
index 00000000..1db76c5d
--- /dev/null
+++ b/kvision-modules/kvision-bootstrap-select/build.gradle.kts
@@ -0,0 +1,68 @@
+buildscript {
+    extra.set("production", (findProperty("prod") ?: findProperty("production") ?: "false") == "true")
+}
+
+plugins {
+    kotlin("js")
+    id("maven-publish")
+}
+
+repositories()
+
+kotlin {
+    kotlinJsTargets()
+}
+
+dependencies {
+    implementation(kotlin("stdlib-js"))
+    api(rootProject)
+    implementation(npm("bootstrap-select", "1.13.12"))
+    implementation(npm("ajax-bootstrap-select", "1.4.5"))
+    testImplementation(kotlin("test-js"))
+}
+
+val sourcesJar by tasks.registering(Jar::class) {
+    archiveClassifier.set("sources")
+    from(kotlin.sourceSets.main.get().kotlin)
+}
+
+publishing {
+    publications {
+        create<MavenPublication>("kotlin") {
+            from(components["kotlin"])
+            artifact(tasks["sourcesJar"])
+            pom {
+                defaultPom()
+            }
+        }
+    }
+}
+
+setupPublication()
+
+fun copyResources() {
+    copy {
+        from("$buildDir/processedResources/Js/main")
+        into("${rootProject.buildDir}/js/packages/kvision-${project.name}/kotlin")
+    }
+    copy {
+        from("$buildDir/processedResources/Js/main")
+        into("${rootProject.buildDir}/js/packages/kvision-${project.name}/kotlin-dce")
+    }
+}
+
+tasks {
+    getByName("JsJar", Jar::class) {
+        from("${rootProject.buildDir}/js/packages/kvision-${project.name}/package.json")
+    }
+    getByName("compileTestKotlinJs") {
+        doLast {
+            copyResources()
+        }
+    }
+    getByName("processDceKotlinJs") {
+        doLast {
+            copyResources()
+        }
+    }
+}