From 41d3978e8fb9d804b0c970188e778fba0c85616e Mon Sep 17 00:00:00 2001
From: Jörg Sommrey <28217714+jo-37@users.noreply.github.com>
Date: Tue, 12 Dec 2023 21:04:07 +0100
Subject: Solution to task 1

---
 challenge-247/jo-37/perl/ch-1.pl | 95 ++++++++++++++++++++++++++++++++++++++++
 1 file changed, 95 insertions(+)
 create mode 100755 challenge-247/jo-37/perl/ch-1.pl

diff --git a/challenge-247/jo-37/perl/ch-1.pl b/challenge-247/jo-37/perl/ch-1.pl
new file mode 100755
index 0000000000..d9f6a01c18
--- /dev/null
+++ b/challenge-247/jo-37/perl/ch-1.pl
@@ -0,0 +1,95 @@
+#!/usr/bin/perl -s
+
+use v5.25;
+use Test2::V0;
+use Graph::Matching 'max_weight_matching';
+use Math::Prime::Util 'forcomb';
+use experimental 'signatures';
+
+our ($tests, $examples);
+
+run_tests() if $tests || $examples;	# does not return
+
+die <<EOS unless @ARGV;
+usage: $0 [-examples] [-tests] [NAME...]
+
+-examples
+    run the examples from the challenge
+ 
+-tests
+    run some tests
+
+NAME...
+    list of names
+
+EOS
+
+
+### Input and Output
+
+print_m(secret_santa(@ARGV));
+
+
+### Implementation
+
+sub same_family {
+    my ($x, $y) = map +(split)[-1], @_;
+    $x eq $y;
+}
+
+sub secret_santa (@names) {
+    return {} if @names % 2;
+    my @graph;
+    forcomb {push @graph, [@names[@_], 1 - same_family(@names[@_])]} @names, 2;
+
+    +{max_weight_matching(\@graph, 1)};
+}
+
+sub print_m {
+    my $m = shift;
+    say "$_ -> $m->{$_}" for keys %$m;
+}
+
+
+### Examples and tests
+
+sub run_tests {
+    SKIP: {
+        skip "examples" unless $examples;
+
+        my $m1 = secret_santa('Mr. Wall', 'Mrs. Wall', 'Mr. Anwar',
+            'Mrs. Anwar', 'Mr. Conway', 'Mr. Cross');
+        subtest 'example 1' => sub {
+            plan 6;
+            ok !same_family($_, $m1->{$_}), 'different families' for keys %$m1;
+        };
+        print_m($m1);
+
+        is secret_santa('Mr. Wall', 'Mrs. Wall', 'Mr. Anwar'), {},
+        'failed example 2';
+    }
+
+    SKIP: {
+        skip "tests" unless $tests;
+        my $m1 = secret_santa('Mr. Wall', 'Mrs. Wall', 'Mr. Anwar', 'A. Wall');
+        subtest 'modified example 2' => sub {
+            plan 3;
+            is scalar %$m1, 4, 'count';
+            !same_family($_, $m1->{$_}) && pass 'different families'
+                for keys %$m1; 
+        };
+        print_m($m1);
+
+        my $m2 = secret_santa('1 A', '2 A', '3 A', '1 B', '2 B', '3 B',
+            '1 C', '2 C', '3 C', '1 D');
+        subtest 'non-trivial case' => sub {
+            plan 10;
+            ok !same_family($_, $m2->{$_}), 'different families' for keys %$m2;
+        };
+        print_m($m2);
+
+	}
+
+    done_testing;
+    exit;
+}
-- 
cgit 


From 32a480a864ef53a82230a306897c0bf991ce539e Mon Sep 17 00:00:00 2001
From: Jörg Sommrey <28217714+jo-37@users.noreply.github.com>
Date: Tue, 12 Dec 2023 21:04:20 +0100
Subject: Solution to task 2

---
 challenge-247/jo-37/perl/ch-2.pl | 56 ++++++++++++++++++++++++++++++++++++++++
 1 file changed, 56 insertions(+)
 create mode 100755 challenge-247/jo-37/perl/ch-2.pl

diff --git a/challenge-247/jo-37/perl/ch-2.pl b/challenge-247/jo-37/perl/ch-2.pl
new file mode 100755
index 0000000000..852871a4d2
--- /dev/null
+++ b/challenge-247/jo-37/perl/ch-2.pl
@@ -0,0 +1,56 @@
+#!/usr/bin/perl -s
+
+use v5.24;
+use Test2::V0 '!float';
+use PDL;
+use PDL::Char;
+
+our ($tests, $examples);
+
+run_tests() if $tests || $examples;	# does not return
+
+die <<EOS unless @ARGV == 1;
+usage: $0 [-examples] [-tests] [S]
+
+-examples
+    run the examples from the challenge
+ 
+-tests
+    run some tests
+
+S
+    string of lower case ascii characters
+
+EOS
+
+
+### Input and Output
+
+say most_frequent_pair(shift);
+
+
+### Implementation
+
+sub most_frequent_pair {
+	my $s = PDL::Char->new(shift);
+    my ($count, $pairs) = rlevec($s->lags(0, 1, $s->dim(0) - 1)->qsortvec);
+    $pairs->atstr($count->long->maximum_ind);
+}
+
+
+### Examples and tests
+
+sub run_tests {
+    SKIP: {
+        skip "examples" unless $examples;
+        is most_frequent_pair('abcdbca'), 'bc', 'example 1';
+        is most_frequent_pair('cdeabeabfcdfabgcd'), 'ab', 'example 2';
+    }
+
+    SKIP: {
+        skip "tests" unless $tests;
+	}
+
+    done_testing;
+    exit;
+}
-- 
cgit 


From 9cb42f2e8bbb904efba417a1ea5cb0862f139f8e Mon Sep 17 00:00:00 2001
From: Jörg Sommrey <28217714+jo-37@users.noreply.github.com>
Date: Tue, 12 Dec 2023 21:03:50 +0100
Subject: Blog for challenge 247

---
 challenge-247/jo-37/blog.txt | 1 +
 1 file changed, 1 insertion(+)
 create mode 100644 challenge-247/jo-37/blog.txt

diff --git a/challenge-247/jo-37/blog.txt b/challenge-247/jo-37/blog.txt
new file mode 100644
index 0000000000..f7ee7c2b00
--- /dev/null
+++ b/challenge-247/jo-37/blog.txt
@@ -0,0 +1 @@
+https://github.sommrey.de/blog/pwc/challenge-247
-- 
cgit