From 0a9b85926bf1bc18770397f058fdb6e4aebebabd Mon Sep 17 00:00:00 2001
From: Polgár Márton <polgar@astron.hu>
Date: Mon, 4 Jul 2022 10:56:38 +0200
Subject: Solution for first task

---
 challenge-172/2colours/raku/ch-1.raku | 32 ++++++++++++++++++++++++++++++++
 1 file changed, 32 insertions(+)
 create mode 100755 challenge-172/2colours/raku/ch-1.raku

diff --git a/challenge-172/2colours/raku/ch-1.raku b/challenge-172/2colours/raku/ch-1.raku
new file mode 100755
index 0000000000..0ee9b236ff
--- /dev/null
+++ b/challenge-172/2colours/raku/ch-1.raku
@@ -0,0 +1,32 @@
+#!/usr/bin/env raku
+
+constant @primes = (1 .. *).grep: &is-prime;
+
+multi prime-partition($sum, $count) {
+  gather samewith $sum, $count, 1, ()
+}
+
+#bound check (could be more accurate for sure)
+sub unfinishable($sum, $count, $chosen-prime) { $sum < $count * $chosen-prime }
+
+#terminating when done
+multi prime-partition($sum, 0, $, @rest) {
+  take @rest if $sum == 0;
+}
+
+#
+multi prime-partition($sum, $count, $lower-bound, @rest) {
+  my &finishable = { !unfinishable($sum, $count, $_) };
+  my @prime-range = lazy @primes.toggle: :off, * > $lower-bound;
+  @prime-range .= toggle: &finishable;
+  samewith $sum - $_, $count - 1, $_, (|@rest, $_) for @prime-range;  
+}
+
+sub MAIN(
+  Int $m,
+  Int $n
+) {
+  say "Input: \$m = $m, \$n = $n";
+  my $output = prime-partition($m, $n).map(*.join: ', ').join: ' or ';
+  say "Output: $output";
+}
\ No newline at end of file
-- 
cgit 


From d917e83557936971ff484560e04ba34eb1a41789 Mon Sep 17 00:00:00 2001
From: Márton Polgár <37218286+2colours@users.noreply.github.com>
Date: Sun, 10 Jul 2022 23:18:01 +0200
Subject: Create ch-2.raku

---
 challenge-172/2colours/raku/ch-2.raku | 18 ++++++++++++++++++
 1 file changed, 18 insertions(+)
 create mode 100644 challenge-172/2colours/raku/ch-2.raku

diff --git a/challenge-172/2colours/raku/ch-2.raku b/challenge-172/2colours/raku/ch-2.raku
new file mode 100644
index 0000000000..141a587750
--- /dev/null
+++ b/challenge-172/2colours/raku/ch-2.raku
@@ -0,0 +1,18 @@
+class IntSample does Associative {
+    has @!data;
+    submethod BUILD(:@data) {
+        @!data = sort @data;
+    }
+    method AT-KEY($scale) {
+        given $scale {
+            when Whatever { @!data[@!data - 1] }
+            when WhateverCode { @!data[.(@!data - 1)] }
+            when Int { @!data[$_] }
+            when * %% 0.5 { (.[$scale.floor] + .[$scale.ceiling]) / 2 given @!data }
+            default { @!data[.round] }
+        }
+    }
+    
+}
+
+say IntSample.new(data => $*IN.lines>>.Int){0,*/4,*/2,* * 3/4, *}
-- 
cgit