From 4484655025de1a65c58feef63b77c7b7f2400d07 Mon Sep 17 00:00:00 2001
From: Jan Krňávek <Jan.Krnavek@gmail.com>
Date: Sun, 6 Sep 2020 19:47:21 +0200
Subject: solution week 076-1

---
 challenge-076/wambash/raku/ch-1.raku | 25 +++++++++++++++++++++++++
 1 file changed, 25 insertions(+)
 create mode 100644 challenge-076/wambash/raku/ch-1.raku

diff --git a/challenge-076/wambash/raku/ch-1.raku b/challenge-076/wambash/raku/ch-1.raku
new file mode 100644
index 0000000000..6749aab021
--- /dev/null
+++ b/challenge-076/wambash/raku/ch-1.raku
@@ -0,0 +1,25 @@
+#!/usr/bin/env raku
+#https://en.wikipedia.org/wiki/Goldbach%27s_conjecture
+#Maybe, it does not work for all natural numbers.
+
+subset OddPrime      of Int where { $_ !%% 2 &       .is-prime };
+subset OddPrimeSucc  of Int where { $_ !%% 2 & ($_-2).is-prime };
+subset Even of Int where *  %% 2;
+
+proto prime-sum ($ where * ≥ 2 ) {*}
+multi prime-sum (              2 --> 1 ) {}
+multi prime-sum (OddPrime      $ --> 1 ) {}
+multi prime-sum (Even          $ --> 2 ) {}
+multi prime-sum (OddPrimeSucc  $ --> 2 ) {}
+multi prime-sum (              $ --> 3 ) {}
+
+sub MAIN (:$test) {
+    use Test;
+    is prime-sum(2),  1;
+    is prime-sum(4),  2;
+    is prime-sum(13), 1;
+    is prime-sum(9),  2;
+    is prime-sum(27), 3;
+    dies-ok { prime-sum(1) };
+    done-testing();
+}
-- 
cgit