From 59634304da95e8237caa5d4dc73f6b711e58d73c Mon Sep 17 00:00:00 2001
From: Jörg Sommrey <28217714+jo-37@users.noreply.github.com>
Date: Fri, 8 Aug 2025 08:56:45 +0200
Subject: Solution to task 2

---
 challenge-333/jo-37/perl/ch-2.pl | 91 ++++++++++++++++++++++++++++++++++++++++
 1 file changed, 91 insertions(+)
 create mode 100755 challenge-333/jo-37/perl/ch-2.pl

diff --git a/challenge-333/jo-37/perl/ch-2.pl b/challenge-333/jo-37/perl/ch-2.pl
new file mode 100755
index 0000000000..6f1fbf30ac
--- /dev/null
+++ b/challenge-333/jo-37/perl/ch-2.pl
@@ -0,0 +1,91 @@
+#!/usr/bin/perl
+
+use v5.26;
+use Test2::V0 -no_srand;
+use Test2::Tools::Subtest 'subtest_streamed';
+use Getopt::Long;
+use experimental 'signatures';
+
+
+### Options and Arguments
+
+my ($tests, $examples, $verbose);
+GetOptions(
+    'examples!' => \$examples,
+    'tests!'    => \$tests,
+    'verbose!'  => \$verbose,
+) or usage();
+
+run_tests($examples, $tests);	# tests do not return
+
+usage() unless @ARGV;
+
+sub usage {
+    die <<~EOS;
+    $0 - duplicate zeros
+
+    usage: $0 [-examples] [-tests] [N...]
+
+    -examples
+        run the examples from the challenge
+     
+    -tests
+        run some tests
+
+    N...
+        list of numbers
+
+    EOS
+}
+
+
+### Input and Output
+
+say "(@{[duplicate_zeros(@ARGV)]})";
+
+
+### Implementation
+#
+# For details see:
+# https://github.sommrey.de/the-bears-den/2025/08/08/ch-333.html#task-2
+
+
+sub duplicate_zeros {
+    (map {($_) x (!$_ + 1)} @_)[0 .. $#_];
+}
+
+
+### Examples and Tests
+
+sub run_tests ($examples, $tests) {
+    return unless $examples || $tests;
+
+    state sub run_example ($args, $expected, $name) {
+        my @result = duplicate_zeros(@$args);
+        is \@result, $expected,
+            "$name: (@$args) -> (@$expected)";
+    }
+
+    plan 2;
+
+    $examples ? subtest_streamed(examples => sub {
+        my @examples = (
+            [[1, 0, 2, 3, 0, 4, 5, 0], [1, 0, 0, 2, 3, 0, 0, 4], 'example 1'],
+            [[1, 2, 3], [1, 2, 3], 'example 2'],
+            [[1, 2, 3, 0], [1, 2, 3, 0], 'example 3'],
+            [[0, 0, 1, 2], [0, 0, 0, 0], 'example 4'],
+            [[1, 2, 0, 3, 4], [1, 2, 0, 0, 3], 'example 5'],
+        );
+        plan scalar @examples;
+        for (@examples) {
+            run_example @$_;
+        }
+    }) : pass 'skip examples';
+
+    $tests ? subtest_streamed(tests => sub {
+        plan 1;
+        pass 'no tests';
+    }) : pass 'skip tests';
+
+    exit;
+}
-- 
cgit