From 7f62afa88d41ec6ffb417a3961e5fbe7155076a4 Mon Sep 17 00:00:00 2001
From: Jörg Sommrey <28217714+jo-37@users.noreply.github.com>
Date: Mon, 13 Oct 2025 16:35:23 +0200
Subject: Solution to task 1

---
 challenge-340/jo-37/perl/ch-1.pl | 92 ++++++++++++++++++++++++++++++++++++++++
 1 file changed, 92 insertions(+)
 create mode 100755 challenge-340/jo-37/perl/ch-1.pl

diff --git a/challenge-340/jo-37/perl/ch-1.pl b/challenge-340/jo-37/perl/ch-1.pl
new file mode 100755
index 0000000000..a310bf6284
--- /dev/null
+++ b/challenge-340/jo-37/perl/ch-1.pl
@@ -0,0 +1,92 @@
+#!/usr/bin/perl
+
+use v5.26;
+use Test2::V0 -no_srand;
+use Test2::Tools::Subtest 'subtest_streamed';
+use Getopt::Long;
+use experimental 'signatures';
+
+
+### Options and Arguments
+
+my ($tests, $examples, $verbose);
+GetOptions(
+    'examples!' => \$examples,
+    'tests!'    => \$tests,
+    'verbose!'  => \$verbose,
+) or usage();
+
+run_tests($examples, $tests);	# tests do not return
+
+usage() unless @ARGV;
+
+sub usage {
+    die <<~EOS;
+    $0 - duplicate removals
+
+    usage: $0 [-examples] [-tests] [STR]
+
+    -examples
+        run the examples from the challenge
+     
+    -tests
+        run some tests
+
+    STR
+        a string
+
+    EOS
+}
+
+
+### Input and Output
+
+say duplicate_removals(shift);
+
+
+### Implementation
+#
+# For details see:
+# https://github.sommrey.de/the-bears-den/2025/10/17/ch-340.html#task-1
+
+
+sub duplicate_removals ($str) {
+    1 while $str =~ s/(.)\1//;
+    $str;
+}
+
+
+### Examples and Tests
+
+sub run_tests ($examples, $tests) {
+    return unless $examples || $tests;
+
+    state sub run_example ($args, $expected, $name) {
+        my $result = duplicate_removals(@$args);
+        is $result, $expected,
+            "$name: (@$args) -> $expected";
+    }
+
+    plan 2;
+
+    $examples ? subtest_streamed(examples => sub {
+        my @examples = (
+            [['abbaca'], 'ca', 'example 1'],
+            [['azxxzy'], 'ay', 'example 2'],
+            [['aaaaaaaa'], '', 'example 3'],
+            [['aabccba'], 'a', 'example 4'],
+            [['abcddcba'], '', 'example 5'],
+        );
+        plan scalar @examples;
+        for (@examples) {
+            run_example @$_;
+        }
+    }) : pass 'skip examples';
+
+    $tests ? subtest_streamed(tests => sub {
+        plan 1;
+        pass 'no tests';
+    }) : pass 'skip tests';
+
+    exit;
+}
-- 
cgit