From 7aa537997fdbde0ba29ed929ad4bd649ad24e16e Mon Sep 17 00:00:00 2001
From: Jörg Sommrey <28217714+jo-37@users.noreply.github.com>
Date: Thu, 1 Aug 2024 14:53:17 +0200
Subject: Solution to task 1

---
 challenge-280/jo-37/perl/ch-1.pl | 74 ++++++++++++++++++++++++++++++++++++++++
 1 file changed, 74 insertions(+)
 create mode 100755 challenge-280/jo-37/perl/ch-1.pl

diff --git a/challenge-280/jo-37/perl/ch-1.pl b/challenge-280/jo-37/perl/ch-1.pl
new file mode 100755
index 0000000000..d507bacfdc
--- /dev/null
+++ b/challenge-280/jo-37/perl/ch-1.pl
@@ -0,0 +1,74 @@
+#!/usr/bin/perl -s
+
+use v5.24;
+use Test2::V0;
+
+our ($tests, $examples);
+
+run_tests() if $tests || $examples;	# does not return
+
+die <<EOS unless @ARGV;
+usage: $0 [-examples] [-tests] [STR]
+
+-examples
+    run the examples from the challenge
+ 
+-tests
+    run some tests
+
+STR
+    a string
+
+EOS
+
+
+### Input and Output
+
+say twice_appearance(shift) // '';
+
+
+### Implementation
+#
+# For details see:
+# https://github.sommrey.de/the-bears-den/2024/08/02/ch-280.html#task-1
+
+
+sub twice_appearance {
+    shift =~ /
+                (.)                 # a single char
+                (?=(.*))            # capture rest of string
+                (
+                    \1.+\2          # stop if current char precedes itself
+                    |               # or
+                    (?<=            # look behind:
+                        (?=         # look ahead:
+                            (?3)    # recursion: stop or look behind
+                        )
+                        .           # one char
+                    )
+                )
+            /x;
+    $1;
+}
+
+
+### Examples and tests
+
+sub run_tests {
+    SKIP: {
+        skip "examples" unless $examples;
+
+        is twice_appearance("acbddbca"), "d", "example 1";
+        is twice_appearance("abccd"), "c", "example 2";
+        is twice_appearance("abcdabbb"), "a", "example 3";
+    }
+
+    SKIP: {
+        skip "tests" unless $tests;
+
+        is twice_appearance("abcde"), U(), "nothing twice";
+	}
+
+    done_testing;
+    exit;
+}
-- 
cgit 


From 07ae39ce24547daece97fcfd0ffdc443e04f8717 Mon Sep 17 00:00:00 2001
From: Jörg Sommrey <28217714+jo-37@users.noreply.github.com>
Date: Thu, 1 Aug 2024 14:53:32 +0200
Subject: Solution to task 2

---
 challenge-280/jo-37/perl/ch-2.pl | 64 ++++++++++++++++++++++++++++++++++++++++
 1 file changed, 64 insertions(+)
 create mode 100755 challenge-280/jo-37/perl/ch-2.pl

diff --git a/challenge-280/jo-37/perl/ch-2.pl b/challenge-280/jo-37/perl/ch-2.pl
new file mode 100755
index 0000000000..eb74dcc92a
--- /dev/null
+++ b/challenge-280/jo-37/perl/ch-2.pl
@@ -0,0 +1,64 @@
+#!/usr/bin/perl -s
+
+use v5.24;
+use Test2::V0;
+
+our ($tests, $examples);
+
+run_tests() if $tests || $examples;	# does not return
+
+die <<EOS unless @ARGV;
+usage: $0 [-examples] [-tests] [STR]
+
+-examples
+    run the examples from the challenge
+ 
+-tests
+    run some tests
+
+STR
+    a string
+
+EOS
+
+
+### Input and Output
+
+say count_asterisks(shift);
+
+
+### Implementation
+#
+# For details see:
+# https://github.sommrey.de/the-bears-den/2024/08/02/ch-280.html#task-2
+
+
+sub count_asterisks {
+    shift =~ s/\|[^|]*\|//rg =~ tr/*//;
+}
+
+
+### Examples and tests
+
+sub run_tests {
+    SKIP: {
+        skip "examples" unless $examples;
+
+        is count_asterisks("p|*e*rl|w**e|*ekly|"), 2, "example 1";
+        is count_asterisks("perl"), 0, "example 2";
+        is count_asterisks("th|ewe|e**|k|l***ych|alleng|e"), 5, "example 3";
+    }
+
+    SKIP: {
+        skip "tests" unless $tests;
+
+        is count_asterisks("*|**|****"), 5, "bar pair";
+        is count_asterisks("*|**|****|"), 5, "trailing bar";
+        is count_asterisks("|*|**|****"), 6, "leading bar";
+        is count_asterisks("|*|**|****|"), 2, "leading and trailing bar";
+        is count_asterisks("*||**|"), 3, "empty part";
+	}
+
+    done_testing;
+    exit;
+}
-- 
cgit 


From 7db360f2e88f962db8d6ebb7626fa03c62b0de5f Mon Sep 17 00:00:00 2001
From: Jörg Sommrey <28217714+jo-37@users.noreply.github.com>
Date: Thu, 1 Aug 2024 14:53:51 +0200
Subject: Blog for challenge 280

---
 challenge-280/jo-37/blog.txt | 1 +
 1 file changed, 1 insertion(+)
 create mode 100644 challenge-280/jo-37/blog.txt

diff --git a/challenge-280/jo-37/blog.txt b/challenge-280/jo-37/blog.txt
new file mode 100644
index 0000000000..c0960adf3e
--- /dev/null
+++ b/challenge-280/jo-37/blog.txt
@@ -0,0 +1 @@
+https://github.sommrey.de/the-bears-den/2024/08/02/ch-280.html
-- 
cgit