From 1fe5253aebbcb4e8c92635f9c6fbb7218b439ac6 Mon Sep 17 00:00:00 2001
From: Jörg Sommrey <28217714+jo-37@users.noreply.github.com>
Date: Tue, 6 Feb 2024 18:04:35 +0100
Subject: Solution to task 1

---
 challenge-255/jo-37/perl/ch-1.pl | 61 ++++++++++++++++++++++++++++++++++++++++
 1 file changed, 61 insertions(+)
 create mode 100755 challenge-255/jo-37/perl/ch-1.pl

diff --git a/challenge-255/jo-37/perl/ch-1.pl b/challenge-255/jo-37/perl/ch-1.pl
new file mode 100755
index 0000000000..1ecc01addb
--- /dev/null
+++ b/challenge-255/jo-37/perl/ch-1.pl
@@ -0,0 +1,61 @@
+#!/usr/bin/perl -s
+
+use v5.24;
+use Test2::V0;
+use experimental 'signatures';
+
+our ($tests, $examples);
+
+run_tests() if $tests || $examples;	# does not return
+
+die <<EOS unless @ARGV == 2;
+usage: $0 [-examples] [-tests] [S T]
+
+-examples
+    run the examples from the challenge
+ 
+-tests
+    run some tests
+
+S T
+    two strings
+
+EOS
+
+
+### Input and Output
+
+say "@{[char_diff(@ARGV)]}";
+
+
+### Implementation
+
+sub char_diff ($s, $t) {
+    my %count;
+    $count{$_}++ for split //, $t;
+    $count{$_}-- for split //, $s;
+    no warnings 'numeric';
+    map +($_) x $count{$_}, keys %count;
+}
+
+
+### Examples and tests
+
+sub run_tests {
+    SKIP: {
+        skip "examples" unless $examples;
+
+        is [char_diff('Perl', 'Preel')], ['e'], 'example 1';
+        is [char_diff('Weekly', 'Weeakly')], ['a'], 'example 2';
+        is [char_diff('Box', 'Boxy')], ['y'], 'example 3';
+    }
+
+    SKIP: {
+        skip "tests" unless $tests;
+
+        is [char_diff('abcde', 'ddd')], ['d', 'd'], 'more than one';
+	}
+
+    done_testing;
+    exit;
+}
-- 
cgit 


From 8e4fffb86e745d51f7b5de19f817330ac7444b71 Mon Sep 17 00:00:00 2001
From: Jörg Sommrey <28217714+jo-37@users.noreply.github.com>
Date: Tue, 6 Feb 2024 18:04:46 +0100
Subject: Solution to task 2

---
 challenge-255/jo-37/perl/ch-2.pl | 65 ++++++++++++++++++++++++++++++++++++++++
 1 file changed, 65 insertions(+)
 create mode 100755 challenge-255/jo-37/perl/ch-2.pl

diff --git a/challenge-255/jo-37/perl/ch-2.pl b/challenge-255/jo-37/perl/ch-2.pl
new file mode 100755
index 0000000000..34336aeabf
--- /dev/null
+++ b/challenge-255/jo-37/perl/ch-2.pl
@@ -0,0 +1,65 @@
+#!/usr/bin/perl -s
+
+use v5.24;
+use Test2::V0;
+use List::UtilsBy 'max_by';
+
+our ($tests, $examples);
+
+run_tests() if $tests || $examples;	# does not return
+
+die <<EOS unless @ARGV > 1;
+usage: $0 [-examples] [-tests] [P W...]
+
+-examples
+    run the examples from the challenge
+ 
+-tests
+    run some tests
+
+P
+    a paragraph
+
+W...
+    list of banned words
+
+EOS
+
+
+### Input and Output
+
+say mfw(@ARGV);
+
+
+### Implementation
+
+sub mfw  {
+    my $p = shift;
+    my %count;
+    $count{$_}++ for split /\W+/, $p;
+    delete @count{@_}; 
+    max_by {$count{$_}} keys %count;
+}
+
+
+### Examples and tests
+
+sub run_tests {
+    SKIP: {
+        skip "examples" unless $examples;
+
+        is mfw('Joe hit a ball, the hit ball flew far after it was hit.',
+            'hit'), 'ball', 'example 1';
+        is mfw('Perl and Raku belong to the same family. Perl is the most popular language in the weekly challenge.',
+            'the'), 'Perl', 'example 2';
+    }
+
+    SKIP: {
+        skip "tests" unless $tests;
+
+        is mfw('one two three four five two three four five three four five four five five', 'two', 'four', 'five'), 'three', 'more banned words';
+	}
+
+    done_testing;
+    exit;
+}
-- 
cgit 


From 19da2726efeaba8c0f314a15a41ddbdfcce4be64 Mon Sep 17 00:00:00 2001
From: Jörg Sommrey <28217714+jo-37@users.noreply.github.com>
Date: Tue, 6 Feb 2024 18:05:50 +0100
Subject: Blog for challenge 255

---
 challenge-255/jo-37/blog.txt | 1 +
 1 file changed, 1 insertion(+)
 create mode 100644 challenge-255/jo-37/blog.txt

diff --git a/challenge-255/jo-37/blog.txt b/challenge-255/jo-37/blog.txt
new file mode 100644
index 0000000000..cf2fd5b28e
--- /dev/null
+++ b/challenge-255/jo-37/blog.txt
@@ -0,0 +1 @@
+https://github.sommrey.de/blog/pwc/challenge-255
-- 
cgit