From 1e984d5512db7388effcb2a1125ed666f4684649 Mon Sep 17 00:00:00 2001
From: Jörg Sommrey <28217714+jo-37@users.noreply.github.com>
Date: Tue, 28 Jan 2025 22:53:12 +0100
Subject: Solution to task 1

---
 challenge-306/jo-37/perl/ch-1.pl | 102 +++++++++++++++++++++++++++++++++++++++
 1 file changed, 102 insertions(+)
 create mode 100755 challenge-306/jo-37/perl/ch-1.pl

diff --git a/challenge-306/jo-37/perl/ch-1.pl b/challenge-306/jo-37/perl/ch-1.pl
new file mode 100755
index 0000000000..727261bfc5
--- /dev/null
+++ b/challenge-306/jo-37/perl/ch-1.pl
@@ -0,0 +1,102 @@
+#!/usr/bin/perl
+
+use v5.26;
+use Test2::V0 '!float';
+use Test2::Tools::Subtest 'subtest_streamed';
+use Getopt::Long;
+use experimental 'signatures';
+
+use PDL;
+use PDL::NiceSlice;
+
+
+### Options and Arguments
+
+my ($tests, $examples, $verbose);
+GetOptions(
+    'examples!' => \$examples,
+    'tests!'    => \$tests,
+    'verbose!'  => \$verbose,
+) or usage();
+
+run_tests($examples, $tests);	# tests do not return
+
+usage() unless @ARGV;
+
+sub usage {
+    die <<~EOS;
+    $0 - odd sum
+
+    usage: $0 [-examples] [-tests] [N...]
+
+    -examples
+        run the examples from the challenge
+     
+    -tests
+        run some tests and
+        print weights for L = 1..10
+
+    N...
+        list of numbers
+
+    EOS
+}
+
+
+### Input and Output
+
+say odd_sum(@ARGV);
+
+
+### Implementation
+#
+# For details see:
+# https://github.sommrey.de/the-bears-den/2025/01/31/ch-306.html#task-1
+
+sub weight ($n) {
+    my $k = int +($n + 1) / 2;
+    cat((1 + sequence $n)->(*$k),
+        ($n - sequence $n)->(*$k),
+        (1 + 2 * sequence $k)->(,*$n),
+        ($n - 2 * sequence $k)->(,*$n)
+    )->mv(2, 0)->minover->sumover;
+}
+
+sub odd_sum {
+    my $l = long [@_];
+    inner($l, weight($l->dim(0)))->sclr;
+}
+
+
+### Examples and Tests
+
+sub run_tests ($examples, $tests) {
+    return unless $examples || $tests;
+
+    state sub run_example ($args, $expected, $name) {
+        my $result = odd_sum(@$args);
+        is $result, $expected,
+            "$name: (@$args) -> " . $expected;
+    }
+
+    plan 2;
+
+    $examples ? subtest_streamed(examples => sub {
+        my @examples = (
+            [[2, 5, 3, 6, 4], 77, 'example 1'],
+            [[1, 3], 4, 'example 2'],
+        );
+        plan scalar @examples;
+        for (@examples) {
+            run_example @$_;
+        }
+    }) : pass 'skip examples';
+
+    $tests ? subtest_streamed(tests => sub {
+        plan 1;
+        say weight($_) for 1 .. 10;
+        is odd_sum(20, 15, 12, 15, 20), 300, '60 * 5';
+    }) : pass 'skip tests';
+
+    exit;
+}
-- 
cgit 


From 432c640a92c1d5b23972b41e2d7a22e5b801e6ab Mon Sep 17 00:00:00 2001
From: Jörg Sommrey <28217714+jo-37@users.noreply.github.com>
Date: Tue, 28 Jan 2025 22:53:29 +0100
Subject: Solution to task 2

---
 challenge-306/jo-37/perl/ch-2.pl | 97 ++++++++++++++++++++++++++++++++++++++++
 1 file changed, 97 insertions(+)
 create mode 100755 challenge-306/jo-37/perl/ch-2.pl

diff --git a/challenge-306/jo-37/perl/ch-2.pl b/challenge-306/jo-37/perl/ch-2.pl
new file mode 100755
index 0000000000..b534674492
--- /dev/null
+++ b/challenge-306/jo-37/perl/ch-2.pl
@@ -0,0 +1,97 @@
+#!/usr/bin/perl
+
+use v5.26;
+use Test2::V0;
+use Test2::Tools::Subtest 'subtest_streamed';
+use Getopt::Long;
+use experimental 'signatures';
+
+use List::MoreUtils qw(nsort_by binsert);
+
+
+### Options and Arguments
+
+my ($tests, $examples, $verbose);
+GetOptions(
+    'examples!' => \$examples,
+    'tests!'    => \$tests,
+    'verbose!'  => \$verbose,
+) or usage();
+
+run_tests($examples, $tests);	# tests do not return
+
+usage() unless @ARGV;
+
+sub usage {
+    die <<~EOS;
+    $0 - last element
+
+    usage: $0 [-examples] [-tests] [-verbose] [N...]
+
+    -examples
+        run the examples from the challenge
+     
+    -tests
+        run some tests
+
+    N...
+        list of numbers
+
+    EOS
+}
+
+
+### Input and Output
+
+say last_element(@ARGV);
+
+
+### Implementation
+#
+# For details see:
+# https://github.sommrey.de/the-bears-den/2025/01/31/ch-306.html#task-2
+
+
+sub last_element {
+    my @list = nsort_by {$_} @_;
+    while (@list > 1) {
+        my ($m1, $m2) = splice @list, -2;
+        my $diff = $m2 - $m1;
+        next unless $diff;
+        binsert {$_ <=> $diff} $diff, @list;
+    }
+    $list[0] // 0;
+}
+
+
+### Examples and Tests
+
+sub run_tests ($examples, $tests) {
+    return unless $examples || $tests;
+
+    state sub run_example ($args, $expected, $name) {
+        my $result = last_element(@$args);
+        is $result, $expected,
+            "$name: (@$args) -> " . $expected;
+    }
+
+    plan 2;
+
+    $examples ? subtest_streamed(examples => sub {
+        my @examples = (
+            [[3, 8, 5, 2, 9, 2], 1, 'example 1'],
+            [[3, 2, 5], 0, 'example 2'],
+        );
+        plan scalar @examples;
+        for (@examples) {
+            run_example @$_;
+        }
+    }) : pass 'skip examples';
+
+    $tests ? subtest_streamed(tests => sub {
+        plan 8;
+        is last_element(map 2**$_ - 1, 1 .. $_), $_, 2**$_ - 1 for 1 .. 8;
+    }) : pass 'skip tests';
+
+    exit;
+}
-- 
cgit 


From 506d6356fed9796931d46821fa4eb70d96cf6517 Mon Sep 17 00:00:00 2001
From: Jörg Sommrey <28217714+jo-37@users.noreply.github.com>
Date: Tue, 28 Jan 2025 22:53:45 +0100
Subject: Blog for challenge 306

---
 challenge-306/jo-37/blog.txt | 1 +
 1 file changed, 1 insertion(+)
 create mode 100644 challenge-306/jo-37/blog.txt

diff --git a/challenge-306/jo-37/blog.txt b/challenge-306/jo-37/blog.txt
new file mode 100644
index 0000000000..71fec76ed5
--- /dev/null
+++ b/challenge-306/jo-37/blog.txt
@@ -0,0 +1 @@
+https://github.sommrey.de/the-bears-den/2025/01/31/ch-306.html
-- 
cgit