plugins {
    id 'net.kyori.blossom' version '1.1.0'
    id 'com.github.johnrengelman.shadow' version '4.0.1'
}

dependencies {
    compile project(':spark-common')
    compileOnly 'com.velocitypowered:velocity-api:1.1.0'
    annotationProcessor 'com.velocitypowered:velocity-api:1.1.0'
}

repositories {
    maven { url "https://repo.velocitypowered.com/releases/" }
}

blossom {
    replaceTokenIn('src/main/java/me/lucko/spark/velocity/VelocitySparkPlugin.java')
    replaceToken '@version@', project.pluginVersion
    replaceToken '@desc@', project.pluginDescription
}

shadowJar {
    archiveName = 'spark-velocity.jar'

    relocate 'okio', 'me.lucko.spark.lib.okio'
    relocate 'okhttp3', 'me.lucko.spark.lib.okhttp3'
    relocate 'org.tukaani.xz', 'me.lucko.spark.lib.xz'
    relocate 'com.google.protobuf', 'me.lucko.spark.lib.protobuf'
    relocate 'org.objectweb.asm', 'me.lucko.spark.lib.asm'

    exclude 'module-info.class'
    exclude 'META-INF/maven/**'
    exclude 'META-INF/proguard/**'
}

artifacts {
    archives shadowJar
    shadow shadowJar
}