plugins {
    id 'net.kyori.blossom' version '1.3.0'
    id 'com.github.johnrengelman.shadow' version '7.0.0'
}

tasks.withType(JavaCompile) {
    // override, compile targeting J11
    options.release = 11
}

dependencies {
    implementation project(':spark-common')
    compileOnly 'com.velocitypowered:velocity-api:4.0.0-SNAPSHOT'
    annotationProcessor 'com.velocitypowered:velocity-annotation-processor:4.0.0-SNAPSHOT'
}

repositories {
    maven { url "https://repo.velocitypowered.com/snapshots/" }
}

blossom {
    replaceTokenIn('src/main/java/me/lucko/spark/velocity/VelocitySparkPlugin.java')
    replaceToken '@version@', project.pluginVersion
    replaceToken '@desc@', project.pluginDescription
}

shadowJar {
    archiveName = "spark-${project.pluginVersion}-velocity4.jar"

    dependencies {
        exclude(dependency('net.kyori:^(?!adventure-text-feature-pagination).+$'))
    }

    relocate 'net.kyori.adventure.text.feature.pagination', 'me.lucko.spark.lib.adventure.pagination'
    relocate 'net.bytebuddy', 'me.lucko.spark.lib.bytebuddy'
    relocate 'com.google.protobuf', 'me.lucko.spark.lib.protobuf'
    relocate 'org.objectweb.asm', 'me.lucko.spark.lib.asm'
    relocate 'one.profiler', 'me.lucko.spark.lib.asyncprofiler'

    exclude 'module-info.class'
    exclude 'META-INF/maven/**'
    exclude 'META-INF/proguard/**'
}

artifacts {
    archives shadowJar
    shadow shadowJar
}