Merge branch 'develop' into feature/sparkle-mac

# Conflicts:
#	.github/workflows/build.yml

3 files changed, 130 insertions, 0 deletions

diff --git a/nix/NIX.md b/nix/NIX.md
new file mode 100644
index 00000000..1ceba9a3
--- /dev/null
+++ b/nix/NIX.md
@@ -0,0 +1,31 @@
+# How to import
+
+To import with flakes use
+```nix
+inputs = {
+  polymc.url = "github:PolyMC/PolyMC";
+};
+
+...
+
+nixpkgs.overlays = [ inputs.polymc.overlay ]; ## Within configuration.nix
+environment.systemPackages = with pkgs; [ polymc ]; ##
+```
+
+To import without flakes use channels:
+
+```
+nix-channel --add https://github.com/PolyMC/PolyMC/archive/master.tar.gz polymc
+nix-channel --update polymc
+nix-env -iA polymc
+```
+
+or alternatively you can use
+
+```
+nixpkgs.overlays = [
+  (import (builtins.fetchTarball "https://github.com/PolyMC/PolyMC/archive/develop.tar.gz")).overlay
+];
+
+environment.systemPackages = with pkgs; [ polymc ];
+```
diff --git a/nix/default.nix b/nix/default.nix
new file mode 100644
index 00000000..94b74354
--- /dev/null
+++ b/nix/default.nix
@@ -0,0 +1,90 @@
+{ stdenv
+, lib
+, fetchFromGitHub
+, cmake
+, ninja
+, jdk8
+, jdk
+, zlib
+, file
+, wrapQtAppsHook
+, xorg
+, libpulseaudio
+, qtbase
+, quazip
+, libGL
+, msaClientID ? ""
+, extraJDKs ? [ ]
+, extra-cmake-modules
+
+  # flake
+, self
+, version
+, libnbtplusplus
+, enableLTO ? false
+}:
+
+let
+  # Libraries required to run Minecraft
+  libpath = with xorg; lib.makeLibraryPath [
+    libX11
+    libXext
+    libXcursor
+    libXrandr
+    libXxf86vm
+    libpulseaudio
+    libGL
+  ];
+
+  # This variable will be passed to Minecraft by PolyMC
+  gameLibraryPath = libpath + ":/run/opengl-driver/lib";
+
+  javaPaths = lib.makeSearchPath "bin/java" ([ jdk jdk8 ] ++ extraJDKs);
+in
+
+stdenv.mkDerivation rec {
+  pname = "polymc";
+  inherit version;
+
+  src = lib.cleanSource self;
+
+  nativeBuildInputs = [ cmake extra-cmake-modules ninja jdk file wrapQtAppsHook ];
+  buildInputs = [ qtbase quazip zlib ];
+
+  dontWrapQtApps = true;
+
+  postUnpack = ''
+    # Copy libnbtplusplus
+    rm -rf source/libraries/libnbtplusplus
+    mkdir source/libraries/libnbtplusplus
+    cp -a ${libnbtplusplus}/* source/libraries/libnbtplusplus
+    chmod a+r+w source/libraries/libnbtplusplus/*
+  '';
+
+  cmakeFlags = [
+    "-GNinja"
+    "-DLauncher_QT_VERSION_MAJOR=${lib.versions.major qtbase.version}"
+  ] ++ lib.optionals enableLTO [ "-DENABLE_LTO=on" ]
+    ++ lib.optionals (msaClientID != "") [ "-DLauncher_MSA_CLIENT_ID=${msaClientID}" ];
+
+  postInstall = ''
+    # xorg.xrandr needed for LWJGL [2.9.2, 3) https://github.com/LWJGL/lwjgl/issues/128
+    wrapQtApp $out/bin/polymc \
+      --set GAME_LIBRARY_PATH ${gameLibraryPath} \
+      --prefix POLYMC_JAVA_PATHS : ${javaPaths} \
+      --prefix PATH : ${lib.makeBinPath [ xorg.xrandr ]}
+  '';
+
+  meta = with lib; {
+    homepage = "https://polymc.org/";
+    description = "A free, open source launcher for Minecraft";
+    longDescription = ''
+      Allows you to have multiple, separate instances of Minecraft (each with
+      their own mods, texture packs, saves, etc) and helps you manage them and
+      their associated options with a simple interface.
+    '';
+    platforms = platforms.unix;
+    license = licenses.gpl3Plus;
+    maintainers = with maintainers; [ starcraft66 kloenk ];
+  };
+}
diff --git a/nix/flake-compat.nix b/nix/flake-compat.nix
new file mode 100644
index 00000000..8b6cb99c
--- /dev/null
+++ b/nix/flake-compat.nix
@@ -0,0 +1,9 @@
+let
+  lock = builtins.fromJSON (builtins.readFile ../flake.lock);
+  inherit (lock.nodes.flake-compat.locked) rev narHash;
+  flake-compat = fetchTarball {
+    url = "https://github.com/edolstra/flake-compat/archive/${rev}.tar.gz";
+    sha256 = narHash;
+  };
+in
+import flake-compat { src = ../.; }