2 files changed, 164 insertions, 0 deletions
diff --git a/nix/pkg/default.nix b/nix/pkg/default.nix
new file mode 100644
index 00000000..074214c4
--- /dev/null
+++ b/nix/pkg/default.nix
@@ -0,0 +1,73 @@
+{
+  lib,
+  stdenv,
+  canonicalize-jars-hook,
+  cmake,
+  cmark,
+  Cocoa,
+  ninja,
+  jdk17,
+  zlib,
+  qtbase,
+  quazip,
+  extra-cmake-modules,
+  tomlplusplus,
+  ghc_filesystem,
+  gamemode,
+  msaClientID ? null,
+  gamemodeSupport ? stdenv.isLinux,
+  self,
+  version,
+  libnbtplusplus,
+}:
+assert lib.assertMsg (stdenv.isLinux || !gamemodeSupport) "gamemodeSupport is only available on Linux";
+  stdenv.mkDerivation rec {
+    pname = "prismlauncher-unwrapped";
+    inherit version;
+
+    src = lib.cleanSource self;
+
+    nativeBuildInputs = [extra-cmake-modules cmake jdk17 ninja canonicalize-jars-hook];
+    buildInputs =
+      [
+        qtbase
+        zlib
+        quazip
+        ghc_filesystem
+        tomlplusplus
+        cmark
+      ]
+      ++ lib.optional gamemodeSupport gamemode
+      ++ lib.optionals stdenv.isDarwin [Cocoa];
+
+    hardeningEnable = lib.optionals stdenv.isLinux ["pie"];
+
+    cmakeFlags =
+      [
+        "-DLauncher_BUILD_PLATFORM=nixpkgs"
+      ]
+      ++ lib.optionals (msaClientID != null) ["-DLauncher_MSA_CLIENT_ID=${msaClientID}"]
+      ++ lib.optionals (lib.versionOlder qtbase.version "6") ["-DLauncher_QT_VERSION_MAJOR=5"]
+      ++ lib.optionals stdenv.isDarwin ["-DINSTALL_BUNDLE=nodeps" "-DMACOSX_SPARKLE_UPDATE_FEED_URL=''"];
+
+    postUnpack = ''
+      rm -rf source/libraries/libnbtplusplus
+      ln -s ${libnbtplusplus} source/libraries/libnbtplusplus
+    '';
+
+    dontWrapQtApps = true;
+
+    meta = with lib; {
+      homepage = "https://prismlauncher.org/";
+      description = "A free, open source launcher for Minecraft";
+      longDescription = ''
+        Allows you to have multiple, separate instances of Minecraft (each with
+        their own mods, texture packs, saves, etc) and helps you manage them and
+        their associated options with a simple interface.
+      '';
+      platforms = with platforms; linux ++ darwin;
+      changelog = "https://github.com/PrismLauncher/PrismLauncher/releases/tag/${version}";
+      license = licenses.gpl3Only;
+      maintainers = with maintainers; [minion3665 Scrumplex getchoo];
+    };
+  }
diff --git a/nix/pkg/wrapper.nix b/nix/pkg/wrapper.nix
new file mode 100644
index 00000000..8d160143
--- /dev/null
+++ b/nix/pkg/wrapper.nix
@@ -0,0 +1,91 @@
+{
+  lib,
+  stdenv,
+  symlinkJoin,
+  prismlauncher-unwrapped,
+  wrapQtAppsHook,
+  qtbase, # needed for wrapQtAppsHook
+  qtsvg,
+  qtwayland,
+  xorg,
+  libpulseaudio,
+  libGL,
+  glfw,
+  openal,
+  jdk8,
+  jdk17,
+  gamemode,
+  flite,
+  mesa-demos,
+  udev,
+  msaClientID ? null,
+  gamemodeSupport ? stdenv.isLinux,
+  textToSpeechSupport ? stdenv.isLinux,
+  jdks ? [jdk17 jdk8],
+  additionalLibs ? [],
+  additionalPrograms ? [],
+}: let
+  prismlauncherFinal = prismlauncher-unwrapped.override {
+    inherit msaClientID gamemodeSupport;
+  };
+in
+  symlinkJoin {
+    name = "prismlauncher-${prismlauncherFinal.version}";
+
+    paths = [prismlauncherFinal];
+
+    nativeBuildInputs = [
+      wrapQtAppsHook
+    ];
+
+    buildInputs =
+      [
+        qtbase
+        qtsvg
+      ]
+      ++ lib.optional (lib.versionAtLeast qtbase.version "6" && stdenv.isLinux) qtwayland;
+
+    postBuild = ''
+      wrapQtAppsHook
+    '';
+
+    qtWrapperArgs = let
+      runtimeLibs =
+        (with xorg; [
+          libX11
+          libXext
+          libXcursor
+          libXrandr
+          libXxf86vm
+        ])
+        ++ [
+          # lwjgl
+          libpulseaudio
+          libGL
+          glfw
+          openal
+          stdenv.cc.cc.lib
+
+          # oshi
+          udev
+        ]
+        ++ lib.optional gamemodeSupport gamemode.lib
+        ++ lib.optional textToSpeechSupport flite
+        ++ additionalLibs;
+
+      runtimePrograms =
+        [
+          xorg.xrandr
+          mesa-demos # need glxinfo
+        ]
+        ++ additionalPrograms;
+    in
+      ["--prefix PRISMLAUNCHER_JAVA_PATHS : ${lib.makeSearchPath "bin/java" jdks}"]
+      ++ lib.optionals stdenv.isLinux [
+        "--set LD_LIBRARY_PATH /run/opengl-driver/lib:${lib.makeLibraryPath runtimeLibs}"
+        # xorg.xrandr needed for LWJGL [2.9.2, 3) https://github.com/LWJGL/lwjgl/issues/128
+        "--prefix PATH : ${lib.makeBinPath runtimePrograms}"
+      ];
+
+    inherit (prismlauncherFinal) meta;
+  }