nix/distribution.nix


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32

{
  inputs,
  self,
  ...
}: {
  perSystem = {pkgs, ...}: {
    packages = let
      ourPackages = self.overlays.default pkgs null;
    in {
      inherit (ourPackages) prismlauncher-qt5-unwrapped prismlauncher-qt5 prismlauncher-unwrapped prismlauncher;
      default = ourPackages.prismlauncher;
    };
  };

  flake = {
    overlays.default = final: _: let
      version = builtins.substring 0 8 self.lastModifiedDate;

      # common args for prismlauncher evaluations
      unwrappedArgs = {
        inherit (inputs) libnbtplusplus;
        inherit (final.darwin.apple_sdk.frameworks) Cocoa;
        inherit self version;
      };
    in rec {
      prismlauncher-qt5-unwrapped = final.libsForQt5.callPackage ./pkg unwrappedArgs;
      prismlauncher-qt5 = final.libsForQt5.callPackage ./pkg/wrapper.nix {prismlauncher-unwrapped = prismlauncher-qt5-unwrapped;};
      prismlauncher-unwrapped = final.qt6Packages.callPackage ./pkg unwrappedArgs;
      prismlauncher = final.qt6Packages.callPackage ./pkg/wrapper.nix {inherit prismlauncher-unwrapped;};
    };
  };
}