Add simple build functional test

1 files changed, 61 insertions, 0 deletions

diff --git a/src/test/groovy/net/fabricmc/loom/SimpleBuildFunctionalTest.groovy b/src/test/groovy/net/fabricmc/loom/SimpleBuildFunctionalTest.groovy
new file mode 100644
index 00000000..4cbd9b8f
--- /dev/null
+++ b/src/test/groovy/net/fabricmc/loom/SimpleBuildFunctionalTest.groovy
@@ -0,0 +1,61 @@
+package net.fabricmc.loom
+
+import org.gradle.testkit.runner.GradleRunner
+import org.junit.Rule
+import org.junit.rules.TemporaryFolder
+import spock.lang.Specification
+import spock.lang.Unroll
+
+import static net.fabricmc.loom.BuildUtils.*
+import static org.gradle.testkit.runner.TaskOutcome.SUCCESS
+
+/**
+ * Created by Mitchell Skaggs on 6/10/2019.
+ */
+class SimpleBuildFunctionalTest extends Specification {
+	@Rule
+	TemporaryFolder testProjectDir = new TemporaryFolder()
+	File settingsFile
+	File buildFile
+	File propsFile
+	File modJsonFile
+	File modExampleFile
+
+	def setup() {
+		settingsFile = testProjectDir.newFile('settings.gradle')
+		buildFile = testProjectDir.newFile('build.gradle')
+		propsFile = testProjectDir.newFile('gradle.properties')
+
+		testProjectDir.newFolder("src", "main", "resources")
+		modJsonFile = testProjectDir.newFile('src/main/resources/fabric.mod.json')
+
+		testProjectDir.newFolder("src", "main", "java", "net", "fabricmc", "example")
+		modExampleFile = testProjectDir.newFile("src/main/java/net/fabricmc/example/ExampleMod.java")
+	}
+
+	@Unroll
+	def "simple build succeeds using Minecraft #mcVersion"() {
+		given:
+		settingsFile << genSettingsFile("simple-build-functional-test")
+		propsFile << genPropsFile(mcVersion, yarnVersion, loaderVersion, fabricVersion)
+		buildFile << genBuildFile()
+		modJsonFile << genModJsonFile()
+		modExampleFile << genModExampleFile()
+
+		when:
+		def result = GradleRunner.create()
+				.withProjectDir(testProjectDir.root)
+				.withArguments('build')
+				.withPluginClasspath()
+				.build()
+
+		then:
+		result.task(":build").outcome == SUCCESS
+
+		where:
+		mcVersion | yarnVersion       | loaderVersion     | fabricVersion
+		'1.14'    | '1.14+build.21'   | '0.4.8+build.155' | '0.3.0+build.184'
+		'1.14.1'  | '1.14.1+build.10' | '0.4.8+build.155' | '0.3.0+build.184'
+		'1.14.2'  | '1.14.2+build.7'  | '0.4.8+build.155' | '0.3.0+build.184'
+	}
+}