1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
|
import org.jetbrains.CrossPlatformExec
import org.jetbrains.SetupMaven
import org.jetbrains.registerDokkaArtifactPublication
val setupMaven by tasks.register<SetupMaven>("setupMaven")
dependencies {
implementation(project(":core"))
implementation("org.apache.maven:maven-core:${setupMaven.mavenVersion}")
implementation("org.apache.maven:maven-plugin-api:${setupMaven.mavenVersion}")
implementation("org.apache.maven.plugin-tools:maven-plugin-annotations:${setupMaven.mavenPluginToolsVersion}")
implementation("org.apache.maven:maven-archiver:2.5")
implementation(kotlin("stdlib-jdk8"))
}
val mavenBuildDir = setupMaven.mavenBuildDir
val mavenBinDir = setupMaven.mavenBinDir
tasks.named<Delete>("clean") {
delete(mavenBuildDir)
delete(mavenBinDir)
}
/**
* Generate pom.xml for Maven Plugin Plugin
*/
val generatePom by tasks.registering(Copy::class) {
val dokka_version: String by project
inputs.property("dokka_version", dokka_version)
from("$projectDir/pom.tpl.xml") {
rename("(.*).tpl.xml", "$1.xml")
}
into(setupMaven.mavenBuildDir)
eachFile {
filter { line ->
line.replace("<maven.version></maven.version>", "<maven.version>${setupMaven.mavenVersion}</maven.version>")
}
filter { line ->
line.replace("<version>dokka_version</version>", "<version>$dokka_version</version>")
}
filter { line ->
line.replace(
"<version>maven-plugin-plugin</version>",
"<version>${setupMaven.mavenPluginToolsVersion}</version>"
)
}
}
}
/**
* Copy compiled classes to [mavenBuildDir] for Maven Plugin Plugin
*/
val syncClasses by tasks.registering(Sync::class) {
dependsOn(tasks.compileKotlin, tasks.compileJava)
from("$buildDir/classes/kotlin", "$buildDir/classes/java")
into("${setupMaven.mavenBuildDir}/classes/java")
preserve {
include("**/*.class")
}
}
val helpMojo by tasks.registering(CrossPlatformExec::class) {
dependsOn(setupMaven, generatePom, syncClasses)
workingDir(setupMaven.mavenBuildDir)
commandLine(setupMaven.mvn, "-e", "-B", "org.apache.maven.plugins:maven-plugin-plugin:helpmojo")
}
val pluginDescriptor by tasks.registering(CrossPlatformExec::class) {
dependsOn(setupMaven, generatePom, syncClasses)
workingDir(setupMaven.mavenBuildDir)
commandLine(setupMaven.mvn, "-e", "-B", "org.apache.maven.plugins:maven-plugin-plugin:descriptor")
}
val sourceJar by tasks.registering(Jar::class) {
archiveClassifier.set("sources")
from(sourceSets["main"].allSource)
}
tasks.named<Jar>("jar") {
dependsOn(pluginDescriptor, helpMojo)
metaInf {
from("${setupMaven.mavenBuildDir}/classes/java/main/META-INF")
}
manifest {
attributes("Class-Path" to configurations.runtimeClasspath.map { configuration ->
configuration.resolve().joinToString(" ") { it.name }
})
}
duplicatesStrategy = DuplicatesStrategy.WARN
}
registerDokkaArtifactPublication("dokkaMavenPlugin") {
artifactId = "dokka-maven-plugin"
}
|
