Merge pull request #9593 from jo-37/contrib

Solutions to challenge 256

3 files changed, 117 insertions, 0 deletions

diff --git a/challenge-256/jo-37/blog.txt b/challenge-256/jo-37/blog.txt
new file mode 100644
index 0000000000..b99574fff2
--- /dev/null
+++ b/challenge-256/jo-37/blog.txt
@@ -0,0 +1 @@
+https://github.sommrey.de/blog/pwc/challenge-256
diff --git a/challenge-256/jo-37/perl/ch-1.pl b/challenge-256/jo-37/perl/ch-1.pl
new file mode 100755
index 0000000000..f1cc4ac2c0
--- /dev/null
+++ b/challenge-256/jo-37/perl/ch-1.pl
@@ -0,0 +1,57 @@
+#!/usr/bin/perl -s
+
+use v5.24;
+use Test2::V0;
+
+our ($tests, $examples);
+
+run_tests() if $tests || $examples;	# does not return
+
+die <<EOS unless @ARGV;
+usage: $0 [-examples] [-tests] [W...]
+
+-examples
+    run the examples from the challenge
+ 
+-tests
+    run some tests
+
+W...
+    list of words
+
+EOS
+
+
+### Input and Output
+
+say maximum_pairs(@ARGV);
+
+
+### Implementation
+
+sub maximum_pairs {
+    (\my %words)->@{@_} = map scalar reverse, @_;
+
+    delete @words{grep $_ eq $words{$_}, keys %words};
+    (grep defined, delete @words{values %words}) / 2; 
+}
+
+
+### Examples and tests
+
+sub run_tests {
+    SKIP: {
+        skip "examples" unless $examples;
+
+        is maximum_pairs("ab", "de", "ed", "bc"), 1, 'example 1';
+        is maximum_pairs("aa", "ba", "cd", "ed"), 0, 'example 2';
+        is maximum_pairs("uv", "qp", "st", "vu", "mn", "pq"), 2, 'example 3';
+    }
+
+    SKIP: {
+        skip "tests" unless $tests;
+	}
+
+    done_testing;
+    exit;
+}
diff --git a/challenge-256/jo-37/perl/ch-2.pl b/challenge-256/jo-37/perl/ch-2.pl
new file mode 100755
index 0000000000..e2109afcc2
--- /dev/null
+++ b/challenge-256/jo-37/perl/ch-2.pl
@@ -0,0 +1,59 @@
+#!/usr/bin/perl -s
+
+use v5.24;
+use Test2::V0;
+use experimental 'signatures';
+
+our ($tests, $examples);
+
+run_tests() if $tests || $examples;	# does not return
+
+die <<EOS unless @ARGV == 2;
+usage: $0 [-examples] [-tests] [S T]
+
+-examples
+    run the examples from the challenge
+ 
+-tests
+    run some tests
+
+S T
+    two strings
+
+EOS
+
+
+### Input and Output
+
+say merge_strings(@ARGV);
+
+
+### Implementation
+
+sub merge_strings ($s, $t) {
+    my $zip;
+	while ($s || $t) {
+        $zip .= ($s && substr($s, 0, 1, '')) . ($t && substr($t, 0, 1, ''));
+    }
+    $zip;
+}
+
+
+### Examples and tests
+
+sub run_tests {
+    SKIP: {
+        skip "examples" unless $examples;
+
+        is merge_strings('abcd', '1234'), 'a1b2c3d4', 'example 1';
+        is merge_strings('abc', '12345'), 'a1b2c345', 'example 2';
+        is merge_strings('abcde', '123'), 'a1b2c3de', 'example 3';
+    }
+
+    SKIP: {
+        skip "tests" unless $tests;
+	}
+
+    done_testing;
+    exit;
+}