week 344 in APL

2 files changed, 29 insertions, 0 deletions

diff --git a/challenge-344/richard-park/apl/ArrayFormCompute.aplf b/challenge-344/richard-park/apl/ArrayFormCompute.aplf
new file mode 100644
index 0000000000..a84a5d42c7
--- /dev/null
+++ b/challenge-344/richard-park/apl/ArrayFormCompute.aplf
@@ -0,0 +1,14 @@
+ ArrayFormCompute←{
+
+     _U_←{⍵⍵⍣¯1⊢⍺ ⍺⍺⍥⍵⍵ ⍵}   ⍝ Under operator
+     AFC←+_U_(10∘⊥)
+⍝ Tests
+     1 2 4 6≢12 AFC 1 2 3 4:∘∘∘
+     4 5 5≢181 AFC 2 7 4:∘∘∘
+     1 0 0 0≢1 AFC 9 9 9:∘∘∘
+     1 9 9 9 9≢9999 AFC 1 0 0 0 0:∘∘∘
+     1 0 0 0≢1000 AFC 0:∘∘∘
+
+     'All tests passed.'
+
+ }
diff --git a/challenge-344/richard-park/apl/ArrayFormation.aplf b/challenge-344/richard-park/apl/ArrayFormation.aplf
new file mode 100644
index 0000000000..3b1f44d9fb
--- /dev/null
+++ b/challenge-344/richard-park/apl/ArrayFormation.aplf
@@ -0,0 +1,15 @@
+ ArrayFormation←{
+
+     AF←{
+         ⍺≡⍥∊⍵[⍋⍺⍳⊃¨⍵]
+     }
+
+⍝ Tests
+     1≢1 2 3 4 AF(2 3)(1)(4):∘∘∘
+     0≢1 2 3 4 AF(1 3)(2 4):∘∘∘
+     1≢5 8 2 9 1 AF(9 1)(5 8)(2):∘∘∘
+     0≢1 2 3 AF(1)(3):∘∘∘
+     1≢7 4 6 AF(7 4 6):∘∘∘
+
+     'All tests passed.'
+ }