Merge pull request #12010 from seaker/master

challenge 321, raku solutions

3 files changed, 40 insertions, 0 deletions

diff --git a/challenge-321/feng-chang/raku/ch-1.raku b/challenge-321/feng-chang/raku/ch-1.raku
new file mode 100755
index 0000000000..e2fd2c80f2
--- /dev/null
+++ b/challenge-321/feng-chang/raku/ch-1.raku
@@ -0,0 +1,6 @@
+#!/bin/env raku
+
+unit sub MAIN(*@ints where +* %% 2);
+
+@ints = +«@ints.sort;
+put +(gather { take (@ints.shift + @ints.pop) / 2 while +@ints }).unique;
diff --git a/challenge-321/feng-chang/raku/ch-2.raku b/challenge-321/feng-chang/raku/ch-2.raku
new file mode 100755
index 0000000000..cbaf1c4b3a
--- /dev/null
+++ b/challenge-321/feng-chang/raku/ch-2.raku
@@ -0,0 +1,10 @@
+#!/bin/env raku
+
+unit sub MAIN(Str:D $s1, Str:D $s2);
+
+put redact($s1) eq redact($s2);
+
+sub redact(Str:D $s is copy --> Str:D) {
+    $s .= subst(/. '#'/) while $s.contains('#');
+    $s
+}
diff --git a/challenge-321/feng-chang/raku/test.raku b/challenge-321/feng-chang/raku/test.raku
new file mode 100755
index 0000000000..4343f0a84c
--- /dev/null
+++ b/challenge-321/feng-chang/raku/test.raku
@@ -0,0 +1,24 @@
+#!/bin/env raku
+
+# The Weekly Challenge 321
+use Test;
+
+sub pwc-test(Str:D $script, Bool :$deeply? = False, *@input) {
+    my ($expect, $assertion) = @input.splice(*-2, 2);
+    my $p = run $script, |@input, :out;
+    if $deeply {
+        is-deeply $p.out.slurp(:close).chomp.words.Bag, $expect, $assertion;
+    } else {
+        is $p.out.slurp(:close).chomp, $expect, $assertion;
+    }
+}
+
+# Task 1, Distinct Average
+pwc-test './ch-1.raku', <1 2 4 3 5 6>, 1, 'Distinct Average: (1,2,4,3,5,6) => 1';
+pwc-test './ch-1.raku', <0 2 4 8 3 5>, 2, 'Distinct Average: (0,2,4,8,3,5) => 2';
+pwc-test './ch-1.raku', <7 3 1 0 5 9>, 2, 'Distinct Average: (7,3,1,0,5,9) => 2';
+
+# Task 2, Backspace Compare
+pwc-test './ch-2.raku', <ab#c ad#c>, 'True',  'Backspace Compare: <ab*c ad*c> => true';
+pwc-test './ch-2.raku', <ab## a#b#>, 'True',  'Backspace Compare: <ab** a*b*> => true';
+pwc-test './ch-2.raku', <a#b c>,     'False', 'Backspace Compare: <a*b c>     => false';