Merge pull request #2472 from gugod/master

gugod's Raku solutions for PWC 081

2 files changed, 48 insertions, 0 deletions

diff --git a/challenge-081/gugod/raku/ch-1.raku b/challenge-081/gugod/raku/ch-1.raku
new file mode 100644
index 0000000000..b84d053ef5
--- /dev/null
+++ b/challenge-081/gugod/raku/ch-1.raku
@@ -0,0 +1,20 @@
+#!/usr/bin/env raku
+
+# raku challenge-081/gugod/raku/ch-1.raku abcdabcd abcdabcdabcdabcd
+# (abcd abcdabcd)
+
+sub MAIN (Str $A, Str $B) {
+    say common-base-string($A, $B);
+}
+
+sub common-base-string (Str $A, Str $B) {
+    return ( base-string($A) ∩ base-string($B) ).keys;
+}
+
+sub base-string (Str $s) {
+    return (1..$s.chars).grep(
+        -> $n {
+            ($s.chars mod $n == 0)
+            && ($s.substr(0,$n) x ($s.chars div $n)) eq $s
+        }).map(-> $n { $s.substr(0,$n) });
+}
diff --git a/challenge-081/gugod/raku/ch-2.raku b/challenge-081/gugod/raku/ch-2.raku
new file mode 100644
index 0000000000..62a014f118
--- /dev/null
+++ b/challenge-081/gugod/raku/ch-2.raku
@@ -0,0 +1,28 @@
+#!/usr/bin/env raku
+
+sub MAIN (Str $input = 'input') {
+    print-frequency-table( word-frequency( IO::Path.new($input) ) );
+}
+
+sub word-frequency ( $fh ) {
+    my %freq;
+    my $prev = '';
+    for $fh.split(/<?wb>/) -> $token {
+        if $token.match(/<:Letter>/) && !($token eq "s" && $prev eq "'") {
+            %freq{$token} += 1;
+        }
+        $prev = $token;
+    }
+
+    return %freq;
+}
+
+sub print-frequency-table ( %freq ) {
+    my %rfreq;
+    for %freq.pairs -> $it {
+        %rfreq{ $it.value }.append( $it.key );
+    }
+    for %rfreq.keys.sort -> $n {
+        say $n ~ ' ' ~ %rfreq{$n}.sort.join(' ');
+    }
+}