- Added solutions by Athanasius.

2 files changed, 88 insertions, 0 deletions

diff --git a/challenge-008/athanasius/perl5/ch-1.pl b/challenge-008/athanasius/perl5/ch-1.pl
new file mode 100644
index 0000000000..0659e1414b
--- /dev/null
+++ b/challenge-008/athanasius/perl5/ch-1.pl
@@ -0,0 +1,49 @@
+use strict;
+use warnings;
+use Const::Fast;
+
+const my $TARGET => 5;
+
+MAIN:
+{
+    my $count = 0;
+
+    # It is known that if any odd number n is perfect, n > 10^1500; so only even
+    # numbers need be considered. By the Euclid-Euler Theorem, an even number n
+    # is a perfect number if and only if n = 2^(k-1)*(2^k-1), where 2^k-1 is
+    # prime. So the perfect numbers are a subset of the positive integers n of
+    # the form n = 2^(k-1)*(2^k-1), where k is a positive integer.
+
+    for (my $k = 1; $count < $TARGET; ++$k)
+    {
+        my $n = (2 ** ($k - 1)) * (2 ** $k - 1);
+
+        if (is_perfect($n))
+        {
+            print "$n\n";
+            ++$count;
+        }
+    }
+}
+
+# A positive integer n is perfect if and only if n is equal to the sum of its
+# positive proper divisors (factors). (Equivalently, n is perfect if and only if
+# it is equal to half the sum of its divisors, where the latter include n
+# itself).
+
+sub is_perfect
+{
+    my ($n) = @_;
+
+    return 0 if $n == 1;              # 1 is not a perfect number
+
+    my $max = int(sqrt($n) + 0.5);
+    my $sum = 1;                      # Every positive integer has 1 as a factor
+
+    for my $d (2 .. $max)
+    {
+        $sum += $d + ($n / $d) if ($n % $d) == 0;
+    }
+
+    return $n == $sum;
+}
diff --git a/challenge-008/athanasius/perl5/ch-2.pl b/challenge-008/athanasius/perl5/ch-2.pl
new file mode 100644
index 0000000000..89bd6dab3a
--- /dev/null
+++ b/challenge-008/athanasius/perl5/ch-2.pl
@@ -0,0 +1,39 @@
+use strict;
+use warnings;
+use Const::Fast;
+
+const my $PREFIX => '  ';
+const my $SPACE  => ' ';
+
+MAIN:
+{
+    my @input  = ('This', 'is', 'a test of the', 'center function');
+    my @output = center(@input);
+
+    print "\n";
+    print $PREFIX . $_ . "\n" for @output;
+}
+
+sub center
+{
+    my @lines = @_;
+    my $max   = 0;
+    my @lengths;
+
+    for my $line (@lines)
+    {
+        my $len = length $line;
+        push @lengths, $len;
+        $max = $len if $len > $max;
+    }
+
+    my @centered;
+
+    for my $i (0 .. $#lines)
+    {
+        my $spaces = int(($max - $lengths[$i]) / 2);
+        push @centered, ($SPACE x $spaces) . $lines[$i];
+    }
+
+    return @centered;
+}