Merge pull request #1837 from Scimon/master

Think this works

1 files changed, 31 insertions, 0 deletions

diff --git a/challenge-065/simon-proctor/raku/ch-2.raku b/challenge-065/simon-proctor/raku/ch-2.raku
new file mode 100644
index 0000000000..85bc73ae4c
--- /dev/null
+++ b/challenge-065/simon-proctor/raku/ch-2.raku
@@ -0,0 +1,31 @@
+#!/usr/bin/env raku
+
+use v6;
+
+sub MAIN (
+    Str $target #= String to search for palindromes.
+) {
+    my $found = False;
+    for ^$target.codes -> $start {
+        my @palindromes = find-palindromes( $target.substr( $start ) );
+        if @palindromes.grep( so * ) {
+            $found = True;
+            for @palindromes { .join(", ").say };
+        }
+    }
+    say -1 if ! $found;    
+}
+
+sub infix:<|,|> (@a,@b) { |@a, |@b }
+
+sub find-palindromes( Str $target ) {
+    my @out;
+    for 2..$target.codes -> $length {
+        my $check = $target.substr( 0, $length );
+        if $check ~~ $check.flip {
+            my @rest = find-palindromes( $target.substr( $length ) );
+            @out = @out |,| ( [ [ $check, ], ] X|,| @rest );
+        }
+    }
+    return @out || [[],];
+}