Challenge 196 Solutions (Raku)

2 files changed, 50 insertions, 0 deletions

diff --git a/challenge-196/mark-anderson/raku/ch-1.raku b/challenge-196/mark-anderson/raku/ch-1.raku
new file mode 100644
index 0000000000..7b844a207b
--- /dev/null
+++ b/challenge-196/mark-anderson/raku/ch-1.raku
@@ -0,0 +1,22 @@
+#!/usr/bin/env raku
+use Test;
+
+is-deeply pattern-acb(3,1,4,2),     (1,4,2);
+is-deeply pattern-acb(1,2,3,4),     ();
+is-deeply pattern-acb(1,3,2,4,6,5), (1,3,2);
+
+sub pattern-acb(+$list)
+{
+    for 0..$list-1 -> $a
+    {
+        for $a+1..$list-1 -> $b
+        {
+            for $b+1..$list-1 -> $c
+            {
+                return $list[$a,$b,$c] if $list[$a] < $list[$c] < $list[$b]
+            }
+        }
+    }        
+
+    return ()
+}
diff --git a/challenge-196/mark-anderson/raku/ch-2.raku b/challenge-196/mark-anderson/raku/ch-2.raku
new file mode 100644
index 0000000000..64ead6051b
--- /dev/null
+++ b/challenge-196/mark-anderson/raku/ch-2.raku
@@ -0,0 +1,28 @@
+#!/usr/bin/env raku
+use Test;
+
+is-deeply range-list(1,3,4,5,7),       ((3,5),);
+is-deeply range-list(1,2,3,6,7,9),     ((1,3), (6,7));
+is-deeply range-list(0,1,2,4,5,6,8,9), ((0,2), (4,6), (8,9));
+
+sub range-list(+$list)
+{
+    my ($h, $t) = (0, 0);
+
+    my $a := gather for $list.rotor(2 => -1, :partial)
+    {
+        if .tail - .head == 1
+        {
+            $t++
+        }
+
+        else
+        {
+            take $h, $t;
+            $t++;
+            $h = $t;
+        }
+    }
+
+    $list[ $a.grep({ .head < .tail }) ]
+}