2 files changed, 139 insertions, 0 deletions
diff --git a/challenge-180/jo-37/perl/ch-1.pl b/challenge-180/jo-37/perl/ch-1.pl
new file mode 100755
index 0000000000..7187cfbfbb
--- /dev/null
+++ b/challenge-180/jo-37/perl/ch-1.pl
@@ -0,0 +1,64 @@
+#!/usr/bin/perl -s
+
+use v5.16;
+use Test2::V0;
+use experimental 'signatures';
+
+our ($tests, $examples);
+
+run_tests() if $tests || $examples;	# does not return
+
+die <<EOS unless @ARGV;
+usage: $0 [-examples] [-tests] [STR]
+
+-examples
+    run the examples from the challenge
+ 
+-tests
+    run some tests
+
+STR
+    string to be examined
+
+EOS
+
+
+### Input and Output
+
+say first_uniq(shift);
+
+
+### Implementation
+
+sub first_uniq ($str) {
+    # Count each character's occurrences.
+    my %cnt;
+    $cnt{$_}++ for split //, $str;
+    # Return the index of the first unique character.
+    $cnt{substr $str, $_, 1} == 1 && return $_ for 0 .. length($str) - 1;
+    # If there is no unique character in the string:
+    -1;
+}
+
+
+### Examples and tests
+
+sub run_tests {
+    SKIP: {
+        skip "examples" unless $examples;
+
+        is first_uniq('Perl Weekly Challenge'), 0, 'example 1';
+        is first_uniq('Long Live Perl'), 1, 'example 2';
+    }
+
+    SKIP: {
+        skip "tests" unless $tests;
+
+        is first_uniq('aa'), -1, 'no unique character';
+        is first_uniq(''), -1, 'empty string';
+        is first_uniq('aa0'), 2, 'find zero';
+	}
+
+    done_testing;
+    exit;
+}
diff --git a/challenge-180/jo-37/perl/ch-2.pl b/challenge-180/jo-37/perl/ch-2.pl
new file mode 100755
index 0000000000..9836d3a652
--- /dev/null
+++ b/challenge-180/jo-37/perl/ch-2.pl
@@ -0,0 +1,75 @@
+#!/usr/bin/perl -s
+
+use v5.16;
+use Test2::V0;
+use experimental 'signatures';
+
+our ($tests, $examples, $trim); 
+
+run_tests() if $tests || $examples;	# does not return
+$trim //= -1;
+
+die <<EOS unless @ARGV;
+usage: $0 [-examples] [-tests] [-trim=LIM] [--] [N1 N2...]
+
+-examples
+    run the examples from the challenge
+ 
+-tests
+    run some tests
+
+-trim=LIM
+    use LIM as trim limit. Default: -1
+
+N1 N2...
+    List to be trimmed
+
+EOS
+
+sub trim_low :prototype($\@);
+
+
+### Input and Output
+
+trim_low($trim, @ARGV);
+say "@ARGV";
+
+
+### Implementation
+
+# The simplistic statement "grep $_ > $i, @n;" cannot be the solution to
+# a PWC task.  There must be something beyond that.  I presume the given
+# array has to be modified. 
+sub trim_low :prototype($\@) ($low, $arr) {
+    # Moving backwards over the array simplifies things as removing an
+    # element does not change the indices of not yet processed items.
+    for (my $i = $#$arr; $i >= 0; $i--) {
+        splice @$arr, $i, 1 if $arr->[$i] <= $low;
+    }
+    # Returning a ref to the modified array.
+    $arr;
+}
+
+
+### Examples and tests
+
+sub run_tests {
+    SKIP: {
+        skip "examples" unless $examples;
+
+        is &trim_low(3, [1, 4, 2, 3, 5]), [4, 5], 'example 1';
+        is &trim_low(4, [9, 0, 6, 2, 3, 8, 5]), [9, 6, 8, 5], 'example 2';
+    }
+
+    SKIP: {
+        skip "tests" unless $tests;
+
+        is do {&trim_low(3, my $arr = [1, 4, 2, 3, 5]); $arr},
+            [4, 5], 'example 1 - modified array';
+        is do {&trim_low(4, my $arr = [9, 0, 6, 2, 3, 8, 5]); $arr},
+            [9, 6, 8, 5], 'example 2 - modified array';
+	}
+
+    done_testing;
+    exit;
+}