blob: fc3ac4c2387034a45e47670ad463f6f33b29c58f (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
|
#!/usr/bin/perl -s
use v5.16;
use Test2::V0;
use Math::Cartesian::Product;
use experimental qw(signatures postderef);
our ($tests, $examples);
run_tests() if $tests || $examples; # does not return
die <<EOS unless @ARGV;
usage: $0 [-examples] [-tests] [N ...]
-examples
run the examples from the challenge
-tests
run some tests
N ...
Find the N-th element of the "CY sequence"
EOS
### Input and Output
say cy($_) for @ARGV;
### Implementation
# Find the n-th element of the CY sequence.
sub cy ($n) {
# CY sequence known so far.
state @cy;
# Current number of digits.
state $digits;
# Augment the calculated CY sequence by blocks having an increasing
# number of digits if the requested element isn't in the list yet.
local $" = '';
push @cy,
cartesian {"@_" !~ /11/} ([1 .. 3]) x ++$digits
while $n > @cy;
# Join the digits of the n-th element.
"$cy[$n - 1]->@*";
}
### Examples and tests
sub run_tests {
SKIP: {
skip "examples" unless $examples;
is cy(5), 13, 'example 1';
is cy(10), 32, 'example 2';
is cy(60), 2223, 'example 3';
}
SKIP: {
skip "tests" unless $tests;
is cy(11), 33, 'last 2-digit element';
is cy(12), 121, 'first 3-digit element';
}
done_testing;
exit;
}
|
