challenge-128/abigail/awk/ch-2.awk


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55

#!/usr/bin/awk

#
# See ../README.md
#

#
# Run as: awk -f ch-2.awk < input-file
#


BEGIN {
    for (i = 0; i < 24 * 60; i ++) {
        trains [i] = 0
    }
}

NR <= 2 {
    for (i = 1; i <= NF; i ++) {
        gsub ("[^0-9:]", "", $i)
        split ($i, chunks, ":")
        minutes = 60 * chunks [1] + chunks [2]
        if (NR == 1) {
            arrivals [i]   = minutes
        }
        else {
            departures [i] = minutes
        }
    }
}

END {
    for (i = 1; i <= length (arrivals); i ++) {
        if (arrivals [i] < departures [i]) {
            for (minute = arrivals [i]; minute <= departures [i]; minute ++) {
                trains [minute] ++
            }
        }
        else {
            for (minute = 0; minute <= departures [i]; minute ++) {
                trains [minute] ++
            }
            for (minute = arrivals [i]; minute < 24 * 60; minute ++) {
                trains [minute] ++
            }
        }
    }
    max = 0
    for (i = 0; i < 24 * 60; i ++) {
        if (max <= trains [i]) {
            max  = trains [i]
        }
    }
    print max
}