1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
|
#!/usr/bin/perl
use warnings;
use strict;
use experimental 'signatures';
use List::Util qw{ max };
# First, find the median. Then distribute elements greater than
# median, median, less than median.
sub wiggle_sort_med(@list) {
return \@list if 1 >= @list;
# There are faster ways to find the median, but I had to celebrate
# the New Year with friends.
my @s = sort { $a <=> $b } @list;
my $median_index = int(@s / 2);
my $gt_median = $median_index;
++$gt_median until $gt_median > $#s || $s[$gt_median] > $s[$median_index];
my $from = $gt_median;
my $to = 1;
my @r;
while ($from <= $#s) {
$r[$to] = $s[$from++];
$to += 2;
}
$from = $gt_median - 1;
while ($s[$from] == $s[$median_index] && $to <= $#s) {
$r[$to] = $s[$from--];
$to += 2;
}
$to = 0;
while ($s[$from] == $s[$median_index] && $to <= $#s) {
$r[$to] = $s[$from--];
die 'No way' if $to < $#r && $r[$to] >= $r[$to + 1];
$to += 2;
}
$from = 0;
while ($to <= $#s) {
$r[$to] = $s[$from++];
$to += 2;
}
return \@r
}
# Depth first.
sub wiggle_sort_df(@list) {
my $m = max(@list);
my $r = _wiggle_prefix([$m + 1], @list);
die 'No way' unless $r;
shift @$r;
return $r
}
# Breadth first. Very slow and memory hungry.
sub wiggle_sort_bf(@list) {
my @agenda = ([]);
while (@{ $agenda[0] } < @list) {
my @next;
for my $w (@agenda) {
for my $l (0 .. $#list) {
my $size = @$w;
push @next, [@$w, $l]
if 0 == $size
|| ($list[ $w->[-1] ] <=> $list[$l]) == (1, -1)[ $size % 2 ]
&& ! grep $_ == $l, @$w;
}
}
@agenda = @next;
die 'No way' unless @agenda;
}
return [@list[ @{ $agenda[0] } ]]
}
sub _wiggle_prefix($prefix, @list) {
return $prefix unless @list;
return [@$prefix, @list] if @list == 1 && $list[0] < $prefix->[-1];
for my $pos1 (0 .. $#list) {
next if $list[$pos1] >= $prefix->[-1];
for my $pos2 (0 .. $#list) {
next if $pos1 == $pos2;
if ($list[$pos1] < $list[$pos2]) {
no warnings 'recursion';
my $r = _wiggle_prefix([@$prefix, @list[$pos1, $pos2]],
@list[ grep $_ != $pos1 && $_ != $pos2,
0 .. $#list ]);
return $r if $r;
}
}
}
return
}
use Test2::V0;
plan(3 * (2 * (2 + 6) + 4));
for my $wiggle_sort (*wiggle_sort_med{CODE},
*wiggle_sort_df{CODE},
*wiggle_sort_bf{CODE}
) {
local *wiggle_sort = $wiggle_sort;
for my $array ([1, 5, 1, 1, 6, 4], # Example 1.
[1, 3, 2, 2, 3, 1], # Example 2.
[1, 2, 3, 4, 5], # Odd number of elements.
[1, 1, 1, 2, 2], # 3 + 2.
[1], # Single element.
[2, 1], # Two elements.
[1, 2, 2, 3], # Can't start with the first one.
[1 .. 11], # To show time complexity.
) {
my $w = wiggle_sort(@$array);
my @sa = sort @$array;
my @sw = sort @$w;
is \@sa, \@sw, "same elements @$w";
my $does_wiggle = 1;
for my $i (1 .. $#$w) {
undef $does_wiggle
if ($w->[ $i - 1 ] <=> $w->[$i]) != ($i % 2 ? -1 : 1)
}
is $does_wiggle, 1, 'wiggles';
}
{ my $e = dies { wiggle_sort(1, 1, 2, 2, 2) };
like $e, qr/No way/, '2+3';
}
{ my $e = dies { wiggle_sort(1, 2, 2, 2) };
like $e, qr/No way/, '1+3';
}
{ my $e = dies { wiggle_sort(1, 1, 1, 2) };
like $e, qr/No way/, '3+1';
}
{ my $e = dies { wiggle_sort(2, 2) };
like $e, qr/No way/, 'same 2';
}
}
use Benchmark qw{ cmpthese };
my @l = (1 .. 5, 1 .. 5);
cmpthese(-25, {
median => sub { wiggle_sort_med(@l) },
df => sub { wiggle_sort_df(@l) },
bf => sub { wiggle_sort_bf(@l) },
});
@l = (1 .. 50) x 50;
cmpthese(-5, {
median => sub { wiggle_sort_med(@l) },
df => sub { wiggle_sort_df(@l) },
# bf => sub { wiggle_sort_bf(@l) }, # OOM.
});
__END__
Rate bf df median
bf 0.864/s -- -100% -100%
df 64595/s 7472329% -- -66%
median 189000/s 21863777% 193% --
Rate df median
df 3.17/s -- -100%
median 1242/s 39031% --
|
