1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
|
#!perl
################################################################################
=comment
Perl Weekly Challenge 256
=========================
TASK #2
-------
*Merge Strings*
Submitted by: Mohammad Sajid Anwar
You are given two strings, $str1 and $str2.
Write a script to merge the given strings by adding in alternative order start-
ing with the first string. If a string is longer than the other then append the
remaining at the end.
Example 1
Input: $str1 = "abcd", $str2 = "1234"
Output: "a1b2c3d4"
Example 2
Input: $str1 = "abc", $str2 = "12345"
Output: "a1b2c345"
Example 3
Input: $str1 = "abcde", $str2 = "123"
Output: "a1b2c3de"
=cut
################################################################################
#--------------------------------------#
# Copyright © 2024 PerlMonk Athanasius #
#--------------------------------------#
#===============================================================================
=comment
Interface
---------
If no command-line arguments are given, the test suite is run.
=cut
#===============================================================================
use v5.32.1; # Enables strictures
use warnings;
use Const::Fast;
use List::MoreUtils qw( mesh );
use Test::More;
const my $USAGE => <<END;
Usage:
Usage:
perl $0 <str1> <str2>
perl $0
<str1> A string
<str2> Another string
END
#-------------------------------------------------------------------------------
BEGIN
#-------------------------------------------------------------------------------
{
$| = 1;
print "\nChallenge 256, Task #2: Merge Strings (Perl)\n\n";
}
#===============================================================================
MAIN:
#===============================================================================
{
my $argc = scalar @ARGV;
if ($argc == 0)
{
run_tests();
}
elsif ($argc == 2)
{
my ($str1, $str2) = @ARGV;
print qq[Input: \$str1 = "$str1", \$str2 = "$str2"\n];
my $merged = merge_strings( $str1, $str2 );
print qq[Output: "$merged"\n];
}
else
{
error( "Expected 0 or 2 arguments, found $argc" );
}
}
#-------------------------------------------------------------------------------
sub merge_strings
#-------------------------------------------------------------------------------
{
my ($str1, $str2) = @_;
my @chars1 = split //, $str1;
my @chars2 = split //, $str2;
my @merged = grep { defined } mesh @chars1, @chars2;
return join '', @merged;
}
#-------------------------------------------------------------------------------
sub run_tests
#-------------------------------------------------------------------------------
{
print "Running the test suite\n";
while (my $line = <DATA>)
{
chomp $line;
my ($test_name, $str1, $str2, $expected) = split / \| /x, $line;
for ($test_name, $str1, $str2, $expected)
{
s/ ^ \s+ //x;
s/ \s+ $ //x;
}
my $merged = merge_strings( $str1, $str2 );
is $merged, $expected, $test_name;
}
done_testing;
}
#-------------------------------------------------------------------------------
sub error
#-------------------------------------------------------------------------------
{
my ($message) = @_;
die "ERROR: $message\n$USAGE";
}
################################################################################
__DATA__
Example 1|abcd |1234 |a1b2c3d4
Example 2|abc |12345|a1b2c345
Example 3|abcde|123 |a1b2c3de
|
