1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
|
#!perl
################################################################################
=comment
Perl Weekly Challenge 280
=========================
TASK #1
-------
*Twice Appearance*
Submitted by: Mohammad Sajid Anwar
You are given a string, $str, containing lowercase English letters only.
Write a script to print the first letter that appears twice.
Example 1
Input: $str = "acbddbca"
Output: "d"
Example 2
Input: $str = "abccd"
Output: "c"
Example 3
Input: $str = "abcdabbb"
Output: "a"
=cut
################################################################################
#--------------------------------------#
# Copyright © 2024 PerlMonk Athanasius #
#--------------------------------------#
#===============================================================================
=comment
Interface
---------
1. If no command-line arguments are given, the test suite is run.
Otherwise:
2. The input string is entered on the command-line.
=cut
#===============================================================================
use v5.32; # Enables strictures
use warnings;
use Const::Fast;
use Test::More;
const my $USAGE => <<END;
Usage:
perl $0 <str>
perl $0
<str> A string of lower case letters
END
#-------------------------------------------------------------------------------
BEGIN
#-------------------------------------------------------------------------------
{
$| = 1;
print "\nChallenge 280, Task #1: Twice Appearance (Perl)\n\n";
}
#===============================================================================
MAIN:
#===============================================================================
{
my $argc = scalar @ARGV;
if ($argc == 0)
{
run_tests();
}
elsif ($argc == 1)
{
my $str = $ARGV[ 0 ];
$str =~ / ^ [a-z]* $ /x or error( qq[Invalid input string "$str"] );
print qq[Input: \$str = "$str"\n];
my $frl = find_first_repeated_letter( $str );
printf "Output: %s\n", $frl eq '' ? '<none>' : qq["$frl"];
}
else
{
error( "Expected 1 or 0 command-line arguments, found $argc" );
}
}
#-------------------------------------------------------------------------------
sub find_first_repeated_letter
#-------------------------------------------------------------------------------
{
my ($str) = @_;
$str =~ / ^ [a-z]* $ /x or die 'Invalid string';
my $frl = '';
my %dict;
for my $letter (split //, $str)
{
if (++$dict{ $letter } > 1)
{
$frl = $letter;
last;
}
}
return $frl;
}
#-------------------------------------------------------------------------------
sub run_tests
#-------------------------------------------------------------------------------
{
print "Running the test suite\n";
while (my $line = <DATA>)
{
chomp $line;
my ($test_name, $str, $expected) = split / \| /x, $line;
for ($test_name, $str, $expected)
{
s/ ^ \s+ //x;
s/ \s+ $ //x;
}
my $frl = find_first_repeated_letter( $str );
is $frl, $expected, $test_name;
}
done_testing;
}
#-------------------------------------------------------------------------------
sub error
#-------------------------------------------------------------------------------
{
my ($message) = @_;
die "ERROR: $message\n$USAGE";
}
################################################################################
__DATA__
Example 1 |acbddbca |d
Example 2 |abccd |c
Example 3 |abcdabbb |a
Empty | |
Singletons|abcdefghijklmnop|
|
