1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
|
#!perl
################################################################################
=comment
Perl Weekly Challenge 283
=========================
TASK #1
-------
*Unique Number*
Submitted by: Mohammad Sajid Anwar
You are given an array of integers, @ints, where every elements appears more
than once except one element.
Write a script to find the one element that appears exactly one time.
Example 1
Input: @ints = (3, 3, 1)
Output: 1
Example 2
Input: @ints = (3, 2, 4, 2, 4)
Output: 3
Example 3
Input: @ints = (1)
Output: 1
Example 4
Input: @ints = (4, 3, 1, 1, 1, 4)
Output: 3
=cut
################################################################################
#--------------------------------------#
# Copyright © 2024 PerlMonk Athanasius #
#--------------------------------------#
#===============================================================================
=comment
Interface
---------
1. If no command-line arguments are given, the test suite is run. Otherwise:
2. A list of integers is entered on the command-line.
=cut
#===============================================================================
use v5.32; # Enables strictures
use warnings;
use Const::Fast;
use Regexp::Common qw( number );
use Test::More;
const my $USAGE => <<END;
Usage:
perl $0 [<ints> ...]
perl $0
[<ints> ...] List of integers in which exactly 1 int appears exactly once
END
#-------------------------------------------------------------------------------
BEGIN
#-------------------------------------------------------------------------------
{
$| = 1;
print "\nChallenge 283, Task #1: Unique Number (Perl)\n\n";
}
#===============================================================================
MAIN:
#===============================================================================
{
if (scalar @ARGV == 0)
{
run_tests();
}
else
{
my @ints = @ARGV;
for (@ints)
{
/ ^ $RE{num}{int} $ /x or error( qq["$_" is not a valid integer] );
$_ += 0; # Normalize (e.g., change -0 to 0)
}
printf "Input: \@ints = (%s)\n", join ', ', @ints;
my $unique_num = find_unique_num( \@ints );
if (defined $unique_num)
{
print "Output: $unique_num\n";
}
else
{
print "\n";
error( 'The input list is invalid' );
}
}
}
#-------------------------------------------------------------------------------
sub find_unique_num
#-------------------------------------------------------------------------------
{
my ($ints) = @_;
my %count;
++$count{ $_ } for @$ints;
my @singletons = grep { $count{ $_ } == 1 } keys %count;
return scalar @singletons == 1 ? $singletons[ 0 ] : undef;
}
#-------------------------------------------------------------------------------
sub run_tests
#-------------------------------------------------------------------------------
{
print "Running the test suite\n";
while (my $line = <DATA>)
{
chomp $line;
my ($test_name, $ints_str, $expected) = split / \| /x, $line;
for ($test_name, $ints_str, $expected)
{
s/ ^ \s+ //x;
s/ \s+ $ //x;
}
my @ints = split / \s+ /x, $ints_str;
my $unique_num = find_unique_num( \@ints );
defined $unique_num or die( 'Invalid test data' );
is $unique_num, $expected, $test_name;
}
done_testing;
}
#-------------------------------------------------------------------------------
sub error
#-------------------------------------------------------------------------------
{
my ($message) = @_;
die "ERROR: $message\n$USAGE";
}
################################################################################
__DATA__
Example 1|3 3 1 |1
Example 2|3 2 4 2 4 |3
Example 3|1 |1
Example 4|4 3 1 1 1 4|3
|
