1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
|
use v6d;
################################################################################
=begin comment
Perl Weekly Challenge 337
=========================
TASK #1
-------
*Smaller Than Current*
Submitted by: Mohammad Sajid Anwar
You are given an array of numbers, @num1.
Write a script to return an array, @num2, where $num2[i] is the count of all
numbers less than or equal to $num1[i].
Example 1
Input: @num1 = (6, 5, 4, 8)
Output: (2, 1, 0, 3)
index 0: numbers <= 6 are 5, 4 => 2
index 1: numbers <= 5 are 4 => 1
index 2: numbers <= 4, none => 0
index 3: numbers <= 8 are 6, 5, 4 => 3
Example 2
Input: @num1 = (7, 7, 7, 7)
Output: (3, 3, 3, 3)
Example 3
Input: @num1 = (5, 4, 3, 2, 1)
Output: (4, 3, 2, 1, 0)
Example 4
Input: @num1 = (-1, 0, 3, -2, 1)
Output: (1, 2, 4, 0, 3)
Example 5
Input: @num1 = (0, 1, 1, 2, 0)
Output: (1, 3, 3, 4, 1)
=end comment
################################################################################
#--------------------------------------#
# Copyright © 2025 PerlMonk Athanasius #
#--------------------------------------#
#===============================================================================
=begin comment
Assumptions
-----------
1. The input numbers are integers.
2. The Task should read:
Write a script to return an array, @num2, where $num2[i] is the count of
all *other* numbers less than or equal to $num1[i].
Interface
---------
1. If no command-line arguments are given, the test suite is run. Otherwise:
2. A non-empty list of integers is entered on the command-line.
3. If the first integer is negative, it must be preceded by "--" to indicate
that it is not a command-line flag.
=end comment
#===============================================================================
use Test;
#-------------------------------------------------------------------------------
BEGIN
#-------------------------------------------------------------------------------
{
"\nChallenge 337, Task #1: Smaller Than Current (Raku)\n".put;
}
#===============================================================================
multi sub MAIN
(
#| A non-empty list of integers
*@num1 where { .elems > 0 && .all ~~ Int:D }
)
#===============================================================================
{
"Input: \@num1 = (%s)\n".printf: @num1.join: ', ';
my UInt @num2 = smaller-than-current( @num1 );
"Output: (%s)\n"\ .printf: @num2.join: ', ';
}
#===============================================================================
multi sub MAIN() # No input: run the test suite
#===============================================================================
{
run-tests();
}
#-------------------------------------------------------------------------------
sub smaller-than-current( List:D[Int:D] $num1 --> List:D[UInt:D] )
#-------------------------------------------------------------------------------
{
my UInt %freq{Int};
++%freq{$_} for @$num1;
my Int @keys = %freq.keys.sort;
my UInt $sum = 0;
my UInt %cum-freq{Int};
for @keys -> Int $key
{
$sum += %freq{$key};
%cum-freq{$key} = $sum;
}
my UInt @num2;
for @$num1 -> Int $num
{
@num2.push: %cum-freq{$num} - 1;
}
return @num2;
}
#-------------------------------------------------------------------------------
sub run-tests()
#-------------------------------------------------------------------------------
{
'Running the test suite'.put;
for test-data.lines -> Str $line
{
my Str ($test-name, $num1-str, $expd-str) = $line.split: / \| /;
for $test-name, $num1-str, $expd-str
{
s/ ^ \s+ //;
s/ \s+ $ //;
}
my Int @num1 = $num1-str.split( / \s+ /, :skip-empty ).map: { .Int };
my UInt @num2 = smaller-than-current( @num1 );
my UInt @expd = $expd-str.split( / \s+ /, :skip-empty ).map: { .Int };
is-deeply @num2, @expd, $test-name;
}
done-testing;
}
#-------------------------------------------------------------------------------
sub USAGE()
#-------------------------------------------------------------------------------
{
my Str $usage = $*USAGE;
$usage ~~ s:g/ ($*PROGRAM-NAME) /raku $0/;
$usage.put;
}
#-------------------------------------------------------------------------------
sub test-data( --> Str:D )
#-------------------------------------------------------------------------------
{
return q:to/END/;
Example 1| 6 5 4 8 |2 1 0 3
Example 2| 7 7 7 7 |3 3 3 3
Example 3| 5 4 3 2 1|4 3 2 1 0
Example 4|-1 0 3 -2 1|1 2 4 0 3
Example 5| 0 1 1 2 0|1 3 3 4 1
END
}
################################################################################
|
