build.gradle


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61

plugins {
    id 'org.cadixdev.licenser' version '0.6.1' apply false
}

allprojects {
    group = 'me.lucko'
    version = '1.10-SNAPSHOT'

    configurations {
        compileClasspath // Fabric-loom needs this for remap jar for some reason
    }
}

subprojects {
    apply plugin: 'java'
    apply plugin: 'idea'
    apply plugin: 'java-library'
    apply plugin: 'org.cadixdev.licenser'

    ext {
        baseVersion = '1.10'
        patchVersion = determinePatchVersion()
        pluginVersion = baseVersion + '.' + patchVersion
        pluginDescription = 'spark is a performance profiling plugin/mod for Minecraft clients, servers and proxies.'
    }

    tasks.withType(JavaCompile) {
        options.encoding = 'UTF-8'
        if (JavaVersion.current() != JavaVersion.VERSION_1_8) {
            options.release = 8
        }
    }

    processResources {
        duplicatesStrategy = DuplicatesStrategy.INCLUDE
    }

    license {
        header = rootProject.file('HEADER.txt')
        include '**/*.java'
    }

    repositories {
        mavenCentral()
        maven { url "https://oss.sonatype.org/content/repositories/snapshots/" }
        maven { url "https://repo.lucko.me/" }
        maven { url "https://jitpack.io" }
    }

}

def determinePatchVersion() {
    def tagInfo = new ByteArrayOutputStream()
    exec {
        commandLine 'git', 'describe', '--tags'
        standardOutput = tagInfo
    }
    tagInfo = tagInfo.toString()

    return tagInfo.contains('-') ? tagInfo.split("-")[1] : 0
}