spark-common/build.gradle


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57

plugins {
    id 'com.google.protobuf' version '0.8.16'
}

dependencies {
    api project(':spark-api')
    implementation 'com.github.jvm-profiling-tools:async-profiler:v2.5'
    implementation 'org.ow2.asm:asm:9.1'
    implementation 'com.google.protobuf:protobuf-javalite:3.15.6'
    implementation 'com.squareup.okhttp3:okhttp:3.14.1'
    implementation 'com.squareup.okio:okio:1.17.3'
    implementation 'net.bytebuddy:byte-buddy-agent:1.11.0'
    implementation 'org.tukaani:xz:1.8'
    api('net.kyori:adventure-api:4.9.3') {
        exclude(module: 'checker-qual')
        exclude(module: 'annotations')
    }
    api('net.kyori:adventure-text-serializer-gson:4.9.3') {
        exclude(module: 'adventure-api')
        exclude(module: 'gson')
    }
    api('net.kyori:adventure-text-serializer-legacy:4.9.3') {
        exclude(module: 'adventure-api')
    }
    implementation('net.kyori:adventure-text-feature-pagination:4.0.0-SNAPSHOT') {
        exclude(module: 'adventure-api')
    }
    compileOnly 'com.google.code.gson:gson:2.7'
    compileOnly 'com.google.guava:guava:19.0'
    compileOnly 'org.checkerframework:checker-qual:3.8.0'
}

processResources {
    from(sourceSets.main.resources.srcDirs) {
        include 'spark/linux/libasyncProfiler.so'
        include 'spark/macosx/libasyncProfiler.so'
    }
}

protobuf {
    protoc {
        if (System.getProperty("os.name") == "Mac OS X" && System.getProperty("os.arch") == "aarch64") {
            path = '/opt/homebrew/bin/protoc'
        } else {
            artifact = 'com.google.protobuf:protoc:3.15.6'
        }
    }
    generateProtoTasks {
        all().each { task ->
            task.builtins {
                java {
                    option 'lite'
                }
            }
        }
    }
}