spark-forge/build.gradle


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64

buildscript {
    repositories {
        maven { url = "http://files.minecraftforge.net/maven" }
    }
    dependencies {
        classpath 'net.minecraftforge.gradle:ForgeGradle:2.3-SNAPSHOT'
    }
}

plugins {
    id 'com.github.johnrengelman.shadow' version '4.0.1'
}

apply plugin: 'net.minecraftforge.gradle.forge'

minecraft {
    version = '1.12.2-14.23.4.2705'
    runDir = 'run'
    mappings = 'snapshot_20171003'

    replaceIn 'me/lucko/spark/forge/SparkForgeMod.java'
    replace '@version@', project.pluginVersion
}

processResources {
    from(sourceSets.main.resources.srcDirs) {
        expand (
                'pluginVersion': project.pluginVersion,
                'pluginDescription': project.pluginDescription
        )
        include 'mcmod.info'
    }
}

dependencies {
    compile project(':spark-common')

    def textWithoutLibs = {
        exclude group: 'com.google.code.gson', module: 'gson'
        exclude group: 'com.google.guava', module: 'guava'
        exclude group: 'net.kyori', module: 'blizzard'
    }

    compile 'net.kyori:text:1.11-1.4.0', textWithoutLibs
}

shadowJar {
    archiveName = 'spark-forge.jar'

    relocate 'okio', 'me.lucko.spark.lib.okio'
    relocate 'okhttp3', 'me.lucko.spark.lib.okhttp3'
    relocate 'net.kyori.text', 'me.lucko.spark.lib.text'
}

artifacts {
    archives shadowJar
    shadow shadowJar
}

reobf {
    shadowJar {
        mappingType = 'SEARGE'
    }
}